Excel-What is a cleaner way in Excel to copy over the data?

Question

I am trying to do an import of data where the amount of items will change daily and I will only have to run the macro to copy the data over to the workbook. What I current have works. I just believe that this is not the most efficient way. I would like to also be able to clear the sheet before copying over the new data.

Sub Data()

    Application.ScreenUpdating = False 'Disables "Screen flashing" between 2 workbooks

    Dim colA As Integer, colAA As Integer
    Dim colB As Integer, colBB As Integer
    Dim colC As Integer, colCC As Integer
    Dim colD As Integer, colDD As Integer
    Dim colE As Integer, colEE As Integer
    Dim colF As Integer, colFF As Integer
    Dim colG As Integer, colGG As Integer
    Dim colH As Integer, colHH As Integer
    Dim colI As Integer, colII As Integer
    Dim colJ As Integer, colJJ As Integer
    Dim colK As Integer, colKK As Integer
    Dim colL As Integer, colLL As Integer
    Dim colM As Integer, colMM As Integer
    Dim colN As Integer, colNN As Integer
    Dim colO As Integer, colOO As Integer

    Dim rowA As Integer, rowAA As Integer
    Dim rowB As Integer, rowBB As Integer
    Dim rowC As Integer, rowCC As Integer
    Dim rowD As Integer, rowDD As Integer
    Dim rowE As Integer, rowEE As Integer
    Dim rowF As Integer, rowFF As Integer
    Dim rowG As Integer, rowGG As Integer
    Dim rowH As Integer, rowHH As Integer
    Dim rowI As Integer, rowII As Integer
    Dim rowJ As Integer, rowJJ As Integer
    Dim rowK As Integer, rowKK As Integer
    Dim rowL As Integer, rowLL As Integer
    Dim rowM As Integer, rowMM As Integer
    Dim rowN As Integer, rowNN As Integer
    Dim rowO As Integer, rowOO As Integer

    Dim wbA As Workbook, wbB As Workbook
    Dim bws As Worksheet

    Set wbA = Workbooks.Open("C:\Users\Carrak\Desktop\Data\New Format\Maximo.xlsx.")
    Set wbB = ThisWorkbook

    colAA = 1 'Replace "1" with the number of the column FROM which you're copying
    colBB = 45 'Replace "1" with the number of the column FROM which you're copying
    colCC = 6 'Replace "1" with the number of the column FROM which you're copying
    colDD = 7 'Replace "1" with the number of the column FROM which you're copying
    colEE = 8 'Replace "1" with the number of the column FROM which you're copying
    colFF = 9 'Replace "1" with the number of the column FROM which you're copying
    colGG = 10 'Replace "1" with the number of the column FROM which you're copying
    colHH = 11 'Replace "1" with the number of the column FROM which you're copying
    colII = 28 'Replace "1" with the number of the column FROM which you're copying
    colJJ = 31 'Replace "1" with the number of the column FROM which you're copying
    colKK = 34 'Replace "1" with the number of the column FROM which you're copying
    colLL = 53 'Replace "1" with the number of the column FROM which you're copying
    colMM = 54 'Replace "1" with the number of the column FROM which you're copying
    colNN = 55 'Replace "1" with the number of the column FROM which you're copying
    colOO = 56 'Replace "1" with the number of the column FROM which you're copying


    colA = 1 'Replace "1" with the number of the column TO which you're copying
    colB = 3 'Replace "1" with the number of the column TO which you're copying
    colC = 5 'Replace "1" with the number of the column TO which you're copying
    colD = 6 'Replace "1" with the number of the column TO which you're copying
    colE = 7 'Replace "1" with the number of the column TO which you're copying
    colF = 8 'Replace "1" with the number of the column TO which you're copying
    colG = 9 'Replace "1" with the number of the column TO which you're copying
    colH = 10 'Replace "1" with the number of the column TO which you're copying
    colI = 11 'Replace "1" with the number of the column TO which you're copying
    colJ = 12 'Replace "1" with the number of the column TO which you're copying
    colK = 13 'Replace "1" with the number of the column TO which you're copying
    colL = 14 'Replace "1" with the number of the column TO which you're copying
    colM = 15 'Replace "1" with the number of the column TO which you're copying
    colN = 16 'Replace "1" with the number of the column TO which you're copying
    colO = 17 'Replace "1" with the number of the column TO which you're copying

    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying
    rowAA = 2 'Replace "1" with the number of the starting row of the column FROM which you're copying

    rowA = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowB = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowC = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowD = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowE = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowF = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowG = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowH = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowI = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowJ = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowK = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowL = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowM = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowN = 2 'Replace "1" with the number of the row of the column TO which you're copying
    rowO = 2 'Replace "1" with the number of the row of the column TO which you're copying


        wbA.Activate

            lastAA = Cells(Rows.Count, colAA).End(xlUp).Row 'This finds the last row of the data of the column FROM which you're copying
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colAA)
        wbB.Sheets("Data").Activate
            Cells(rowA, colA) = yourData
            rowA = rowA + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colBB)
            wbB.Sheets("Data").Activate
            Cells(rowB, colB) = yourData
            rowB = rowB + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colCC)
            wbB.Activate
            Cells(rowC, colC) = yourData
            rowC = rowC + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colDD)
        wbB.Activate
            Cells(rowD, colD) = yourData
            rowD = rowD + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colEE)
        wbB.Activate
            Cells(rowE, colE) = yourData
            rowE = rowE + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colFF)
        wbB.Activate
            Cells(rowF, colF) = yourData
            rowF = rowF + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colGG)
        wbB.Activate
            Cells(rowG, colG) = yourData
            rowG = rowG + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colHH)
        wbB.Activate
            Cells(rowH, colH) = yourData
            rowH = rowH + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colII)
        wbB.Activate
            Cells(rowI, colI) = yourData
            rowI = rowI + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colJJ)
            wbB.Activate
            Cells(rowJ, colJ) = yourData
            rowJ = rowJ + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colKK)
        wbB.Activate
            Cells(rowK, colK) = yourData
            rowK = rowK + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colLL)
        wbB.Activate
            Cells(rowL, colL) = yourData
            rowL = rowL + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colMM)
            wbB.Activate
            Cells(rowM, colM) = yourData
            rowM = rowM + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colNN)
        wbB.Activate
            Cells(rowN, colN) = yourData
            rowN = rowN + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
            For x = rowAA To lastAA 'Loops through all the rows of A
        wbA.Activate
            yourData = Cells(x, colOO)
        wbB.Activate
            Cells(rowO, colO) = yourData
            rowO = rowO + 1 'Increments the current line of destination workbook
            Next x 'Skips to next row
        Application.ScreenUpdating = True 'Re-enables Screen Updating

End Sub

Couldn't you just copy and paste the data instead of switching back and forth between workbooks A and B for each cell? — yu_ominae, Jul 30 '14 at 04:28

score 3 · Answer 1 · answered Jul 30 '14 at 05:44

There are a number of things that can be improved here:

Specify your WorkSheet's, rather than rely on yhe implicit ActiveSheet
Use the object references rather than activating the books/sheets
Use a more compact and easily iterated data structure, eg an Array
Seperate the repeated code (copying) into a separate routine
Copy each whole range in one go, rather than looping

Something like this:

Sub Demo()
    ' Declare all your variables
    Dim wbA As Workbook, wbB As Workbook
    Dim wsA As Worksheet, wsB As Worksheet

    Dim Data() As Variant
    Dim i As Long

    ' Specify Source and Destination, Workbook and WorkSheet
    Set wbA = Workbooks.Open("C:\Users\Carrak\Desktop\Data\New Format\Maximo.xlsx.")
    Set wsA = wbA.Worksheets("SpecifySheetName")

    Set wbB = ThisWorkbook
    Set wsB = wbA.Worksheets("SpecifySheetName")

    ' Set up source and destination data
    '    RowFrom , ColFrom, RowTo, ColTo
    Data = Array( _
      Array(2, 1, 2, 1), _
      Array(2, 45, 2, 3), _
      Array(2, 6, 2, 5), _
      Array(2, 7, 2, 6), _
      Array(2, 8, 2, 7), _
      Array(2, 9, 2, 8), _
      Array(2, 10, 2, 9), _
      Array(2, 11, 2, 10), _
      Array(2, 28, 2, 11), _
      Array(2, 31, 2, 12), _
      Array(2, 34, 2, 13), _
      Array(2, 53, 2, 14), _
      Array(2, 54, 2, 15), _
      Array(2, 55, 2, 16), _
      Array(2, 56, 2, 17))

    ' Clear Destination sheet
    wsB.Cells.Clear

    ' Copy Data
    For i = LBound(Data, 1) To UBound(Data, 1)
        CopyData wsA, Data(i)(0), Data(i)(1), wsB, Data(i)(2), Data(i)(3)
    Next
End Sub

Sub CopyData(wsSource As Worksheet, rwSource As Variant, clSource As Variant, _
  wsDest As Worksheet, rwDest As Variant, clDest As Variant)
    Dim rng As Range
    With wsSource
        Set rng = .Range(.Cells(rwSource, clSource), .Cells(.Rows.Count, clSource).End(xlUp))
    End With

    With wsDest
        .Cells(rwDest, clDest).Resize(rng.Rows.Count, rng.Columns.Count).Value = _
          rng.Value
    End With
End Sub

Tyger Guzman · Answer 2 · 2014-07-30T05:58:58.440

For clearing the sheet :

Sheets("sheet1").Select

Selection.AutoFilter

Sheets("sheet1").Cells.Clear

If the file name for the copying sheet is always the same you could possibly try : recording a macro of copy and pasting the all data over wether its copying all data or entire sheet, then go in and manipulate the code from the activesheet format to specifying the paths like you've already on you coding.

Possibly recording a macro and right click the sheet tab and choose to copy or move.

score 0 · Answer 3 · answered Jul 30 '14 at 08:46

I think it is simpler to use a data connections for such tasks. This way you can simply refresh the data via Data->Connections->Refresh.

More here: https://www.google.pl/search?sourceid=chrome-psyapi2&ion=1&espv=&ie=UTF-8&q=data%20connection%20to%20excel%20workbook

Or: I also created a simple Add-In for running SQL queries on Excel data (running the query once will create the data connections).

You can lookup the Add-In here: http://blog.tkacprow.pl/?p=91
Lets say you have a workbook named Source.xlsx with data (two data columns "A" and "B") in worksheet named "Sheet1" and you want to copy the data to the current workbook. The SQL will be:
```
SELECT `Sheet1$`.A, `Sheet1$`.B FROM `C:\Users\USERNAME\Desktop\Source.xlsx`.`Sheet1$` `Sheet1$`
```

This will copy all the data from column named "A" and column "B" of worksheet "Sheet1" of the Source.xlsx workbook to the data range specified in the first parameter of the form. 3. To refresh the data simply go to Data->Connections, find the connection and click refresh

Tyger Guzman · Answer 4 · 2014-07-30T07:14:10.313

Give this a shot:

Sub Test()
' Declare all your variables
Dim wbA As Workbook, wbB As Workbook


Application.ScreenUpdating = False
' Specify Source and Destination, Workbook and WorkSheet

Set wbA = Workbooks.Open("C:\Users\Carrak\Desktop\Data\New Format\Maximo.xlsx.")
Set wbB = ThisWorkbook


wbB.Sheets("Data").Select
Selection.AutoFilter
wbB.Sheets("Data").Cells.Clear


wbA.sheets("sheet1").range("A1:Z500").copy 'change sheet1 as needed A1:Z500 to your range
wbB.sheets("Data").range("A1").pastespecial 'change sheet1 as needed


wbB.Save
wbA.Close 
wbB.Activate 
Application.ScreenUpdating = True 'Re-enables Screen Updating

End sub ()

Or the below since amount of data is dynamic by day.

wbA.sheets("sheet1").cells.copy

Instead of

wbA.sheets("sheet1").range("A1:Z500").copy

Don't know for sure if you'll need the wbA.Activate before the copy and wbB.Activate before the paste. :-) — Tyger Guzman, Jul 30 '14 at 06:50

Excel-What is a cleaner way in Excel to copy over the data?

4 Answers4