Why are two seemingly identical dynamic array types deemed not assignment compatible?

Question

Just a little question, I'm not finding a specific answer so i guessed it might be faster to ask here.

The compiler rejects the code below with the following error:

incompatible types 'dynamic array' and 'array of string'

TMailInfo = record
  FileName,
  MailAdresse,
  MailBCC,
  MailCC,
  MailBetreff: string;
  MailText,
  Anhang: array of string;
  MailAcknowledge,
  MailTXT: Boolean
end;

class function TEMail.SendOutlookCOMMail(aFileName, aMailAdresse, 
  aMailBCC, aMailCC, aMailBetreff: string; 
  aMailText, aAnhang: array of string; 
  const aMailAcknowledge, aMailTXT: Boolean): Boolean;
var
  mailInfo: TMailInfo;
begin
...
  mailInfo.MailBetreff := aMailBetreff;  // these two lines cause the error
  mailInfo.MailText := aMailText;
...
end;

What am I doing wrong? Both are arrays of string, so I don't get why one seems to be dynamic.

Some general advice. Use const params where possible. It expresses intent better, and lets the compiler make optimisations. — David Heffernan, Jul 18 '14 at 07:04
Yeah, that's true, I will refactor that, too - it's not my code I'm working on, I'm just extending the functionalities — Florian Koch, Jul 18 '14 at 07:07
Link, as it seems duplicated to http://stackoverflow.com/q/22140387/460775 — EMBarbosa, Jun 10 '16 at 18:31

score 10 · Accepted Answer · answered Jul 18 '14 at 06:43

You cannot readily assign to MailText and Anhang because you cannot declare another object with a compatible type. That's because you used a dynamic array type inline in your record declaration. You really need to use a type that can be named. To illustrate a bit better, consider this:

X: array of Integer;
Y: array of Integer;

Now X and Y are of different types and X := Y does not compile.

The other problem is your open array parameter. An open array parameter is assignment compatible with nothing. You can copy element by element, but you cannot assign the array in one go.

The best way out of this is to declare the field like this:

MailText,
Anhang: TArray<string>;

And change the open array parameters in the function to also be of that type.

Then you need to decide whether you want to copy the reference or the array:

MailText := aMailText; // copy reference, or
MailText := Copy(aMailText); // copy array

Thanks, that worked - I'll accept as soon as I am allowed to do so — Florian Koch, Jul 18 '14 at 06:46

Rudy Velthuis · Answer 2 · 2014-07-18T07:01:54.743

5

You have two problems. First, as David says, two declarations of a type that look the same, but are declared separately, make them different, assignment incompatible types.

Weirdly enough, this is not so for generic types, like TArray<string>, so it makes sense to use that, if you version of Delphi supports it.

But the second problem is that you are confusing an open array parameter like aMailText with a dynamic array like mailInfo.MailText. aMailText, the parameter, is not necessarily a dynamic array at all, it can be any kind of array.

Take a look at the documentation: Open Arrays

Another explanation: Open array parameters and array of const

edited Jul 18 '14 at 07:01

answered Jul 18 '14 at 06:52

Rudy Velthuis

28,387
5
46
94

thanks for the suggestion, I really didn't think that much about the specifics but now it makes sense – Florian Koch Jul 18 '14 at 06:54
@Rudy you wrote your answer to suggest that I'd not covered open array parameter issue – David Heffernan Jul 18 '14 at 07:30
At the time of reading, you hadn't, AFAICS. Did I miss it? If so, I'm sorry. – Rudy Velthuis Jul 18 '14 at 07:38
It was always there. It's fine. I just wanted to defend myself! :-) – David Heffernan Jul 18 '14 at 07:53
OK, I must have missed it, sorry. – Rudy Velthuis Jul 18 '14 at 07:58

Why are two seemingly identical dynamic array types deemed not assignment compatible?

2 Answers2

Linked