How to use cut and awk commands to extract text input in a tabular format?

Question

I have file input.txt as below:

filename: test1.v

BUG: bug 102 is fixed by some user
IO_CHANGE: there is no io_change for this version
FEATURE: no feature added

filename: test2.v

BUG: bug 103 is fixed by some user 
also bug 105 is fixed
IO_CHANGE: there is no io_change for this version
FEATURE: yes feature number 3 also feature 23
and feature 34 is added

filename: test3.v

BUG: bug 104 is fixed by some user
FEATURE: yes feature number 2
IO_CHANGE:

My Question:- sometimes there is a long description for BUG/FEATURE/IO_CHANGE which is coming in 2 lines or sometimes there is nothing in IO_CHANGE so it is blank. Output file should have list for all bugs then features and io_changes. Those 3 types can be in any order in input file, I need to find all bugs/features/io_changes from the file and list them column wise.

enter image description here

MrFlick · Answer 1 · 2014-06-20T12:58:53.110

How about this. We store the values in an array for each file. Here i concatenate entries that appear on multiple rows.

awk 'function dump() {if (vc>0) 
        print fn, vals["BUG"], vals["FEATURE"], vals["IO_CHANGE"]
    } 
    BEGIN {FS=":";OFS="\t";vc=0} 
    FNR==1 {dump();val=""; delete vals; fn=FILENAME; vc=0} 
    NF>1 {val=$1; vals[val]=vals[val] $2; vc++} 
    NF==1 {vals[val] = vals[val] " " $1} 
    END{dump()}' test*v

The dump() function is what writes a record out to the file.
The BEGIN assigns the ":" to the field separator (so no ":" are allowed as text in fields in this solution). The output is delimited by tab.
Then at the start of each file (FNR=1) we dump records if we have any, and then we reset or collections.
Then, if a line has a ":" (which would result in NF>1) we keep track of which value we are setting and store it in the array. If there is no ":" (making NF==1) then we just add to the last value we were adding to.
Finally, at the end of the last file, we dump the contents one last time.

Due to the fact that you are printing `$2` and using `:` as `FS` no lines without `:` will be printed — , Jun 20 '14 at 08:11
Thanks @Jidder. I had a type in the `NF==1` condition. It now correctly collapses multiple lines. — MrFlick, Jun 20 '14 at 12:59

score 0 · Answer 2 · answered Jun 20 '14 at 08:54

Sets a variable if phrase is found, if one of the other phrases is found unsets it, then save the lines to array based on filename.
Removes everything before : on each line
Then prints the line in columns

#!/bin/bash

awk     'BEGIN{printf("%-8s%-60s%-60s%-20s\n\n","FILE","|BUG","|IO","|FEATURE")}
    /BUG/{a=1}/IO_CHANGE:/ || /FEATURE/{a=0} {if (a){Bug[FILENAME]=Bug[FILENAME]""$0" "}}
    /IO_CHANGE:/{b=1}/BUG/ || /FEATURE/{b=0} {if (b){IO[FILENAME]=IO[FILENAME]$0" "}}
    /FEATURE/{c=1}/IO_CHANGE:/ || /BUG/{c=0} {if (c){Feat[FILENAME]=Feat[FILENAME]$0" "}}
     END{
             for (k in Bug){
                    Bug[k] = substr(Bug[k],index(Bug[k],":"))
                    IO[k] = substr(IO[k],index(IO[k],":"))
                    Feat[k] = substr(Feat[k],index(Feat[k],":"))
                    printf("%-8s%-60s%-60s%-20s\n\n","|"k,"|"Bug[k],"|"IO[k],"|"Feat[k])}}
'  test*v

Unfortunately this wont print multiple lines for each file

How to use cut and awk commands to extract text input in a tabular format?

2 Answers2