How to write spock tests for a service in grails?

Question

I have a grails application with a service called MySampleservice.groovy in grails-app/services/com/myapp/

The service has a method:

boolean spockTest() {
    return false;
}

I've added this in my BuildConfig.groovy

    test(":spock:0.7") {
        exclude "spock-grails-support"
    }

Question

• How/Where should I write a spock test for this service?
• How would I run it?

Answer 1

A simple service:

// grails-app/services/com/myapp/MySampleService.groovy
package com.myapp

class MySampleService {

    def someMethod(String arg) {
        arg?.toUpperCase()
    }
}

A Spock Spec for that service:

// test/unit/com/myapp/MySampleServiceSpec.groovy
package com.myapp

import grails.test.mixin.TestFor
import spock.lang.Specification

@TestFor(MySampleService)
class MySampleServiceSpec extends Specification {

    void "test someMethod"() {
        expect:
        service.someMethod(null) == null
        service.someMethod('Thin Lizzy') == 'THIN LIZZY'
    }
}

You can run the test with grails test-app unit:.

You didn't mention what version of Grails you are using. With 2.4.0 you won't need to make any mention of Spock in your BuildConfig.groovy in order for that to work.

Answer 2

Your are not doing any thing in your service method, you can test it as

@TestFor(MySampleService)
class MySampleServiceSpec extends Specification {

    def setup() {
    }

    def cleanup() {
    }

    void "test something"() {
        when:
        def result = service.spockTest()

        then:
        assert result == false
    }
}

A service is generally used for database interaction, such as saving the data, lets take a simple example, following is my service method

Comment spockTest(String comment) {
    Comment commentInstance = new Comment(comment: comment).save()
    return commentInstance
}

then I generally test this as

@TestFor(MySampleService)
@Mock([Comment])
class MySampleServiceSpec extends Specification {

    def setup() {
    }

    def cleanup() {
    }

    void "test something"() {
        given:
        Integer originalCommentCount = Comment.count()

        when:
        def result = service.spockTest('My Comment')

        then:
        assert originalCommentCount + 1 == Comment.count()
        assert result.comment == "My Comment"
    }
}

Where Comment is my domain class.

I run this test as grails test-app -unit MySampleServiceSpec