Iterate through XML data using Perl module XML::LibXML

Question

Can anyone please translate this (XML::DOM to XML::LibXML)?

I have been at it for hours so I won't put up all of the code that I have tried as it would fill pages

foreach my $review ($review_details->getElementsByTagName("review")) { # find the node review{

  # scroll through each review to get the details that we want

  foreach my $details ($review->getChildNodes) {

    if ($details->getNodeName eq "movie_title") {
      foreach my $movie_title ($details->getChildNodes) {
        print $movie_title->getNodeValue . "\n";
      }
    }

    if ($details->getNodeName eq "reviewer") {
      foreach my $reviewer ($details->getChildNodes) {
        print $reviewer->getNodeValue . "\n";
      }
    }

  }
}

and this is a basic representation of the data

<results>
  <review>
    <movie_title>First Movie</movie_title>
    <reviewer>Annie</reviewer>
  </review>
  <review>
    <movie_title>Second Movie</movie_title>
    <reviewer>Bob</reviewer>
  </review>
  <review>
    <movie_title>Third Movie</movie_title>
    <reviewer>Charlie</reviewer>
  </review>
  <review>
    <movie_title>Fourth Movie</movie_title>
    <reviewer>Don</reviewer>
  </review>
</results>

Some of the things that I tried using XML::LibXML involved different versions of lines such as

foreach my $review ($review_details>findnodes('//display_name')) { 
  print $review->findvalue('movie_title')
}

You original code using XML::DOM doesn't work. $details is a string (node name), you can't call any methods on it. — choroba, May 15 '14 at 10:05
Darn - I'll try to work it out and edit the post. Thanks for pointing it out — Keryn Drake, May 15 '14 at 10:38
I edited the code - it was the foreach my $details line (I had getNodeName but it is getChildNodes — Keryn Drake, May 15 '14 at 11:12
That will teach me for trying to simplify some code - should be correct now - what would be the equivalent with XML::LibXML Cheers — Keryn Drake, May 15 '14 at 11:21
possible duplicate of [Iterating over nodes using XML::LibXML](http://stackoverflow.com/questions/5894789/iterating-over-nodes-using-xmllibxml) — Joe, May 15 '14 at 11:24

score 2 · Answer 1 · answered May 15 '14 at 12:25

This is very straightforward if you use XPath expressions and iterate over all the review elements.

use strict;
use warnings;

use XML::LibXML;

my $doc = XML::LibXML->load_xml(IO => *DATA);

for my $review ( $doc->findnodes('/results/review') ) {
  print $review->findvalue('movie_title'), "\n";
  print $review->findvalue('reviewer'), "\n";
}

__DATA__
<results>
  <review>
    <movie_title>First Movie</movie_title>
    <reviewer>Annie</reviewer>
  </review>
  <review>
    <movie_title>Second Movie</movie_title>
    <reviewer>Bob</reviewer>
  </review>
  <review>
    <movie_title>Third Movie</movie_title>
    <reviewer>Charlie</reviewer>
  </review>
  <review>
    <movie_title>Fourth Movie</movie_title>
    <reviewer>Don</reviewer>
  </review>
</results>

output

First Movie
Annie
Second Movie
Bob
Third Movie
Charlie
Fourth Movie
Don

score 1 · Accepted Answer · answered May 15 '14 at 11:21

I'd probably not use so many loops in XML::LibXML:

#!/usr/bin/perl
use warnings;
use strict;

use XML::LibXML;

my $review_details = 'XML::LibXML'->load_xml( location => shift );

for my $review ($review_details->findnodes('/results/review')) {
    print $review->findvalue($_), "\n" for 'movie_title', 'reviewer';
}

Or, I'd use XML::XSH2, a wrapper around XML::LibXML:

open file.xml ;
for /results/review echo :s (movie_title) {"\n"} (reviewer) ;

Iterate through XML data using Perl module XML::LibXML

2 Answers2