perl code for checking for interval

Question

input file1: it contains lower limit and upper limit

1:     3     5  
2:    4     7  
3:     8     10  
4:    5     10  
5:    10    15  
6:    10    20  
7:     15    30  
8:    30    40

input file 2: it contains certain values

file 3:it also contains some values

output:

1    a b      file2  
2    b c d    file2  
3      
4    c d      file2  
5    b        file3  
6    b        file3  
7    d        file3    
8    c d      file3

I have three file. file1 contains the range and file2 or file3 contains certain values. now we have to check for their interval id from file 1 and print the output for a hit i.e., if a value belongs to any interval then it must print the interval id , value id and the file it come from .

#!/bin/usr/perl -w  
use strict ;  
open (R1,"$file1.txt")|| die;  
open (R2,"$file2.txt")|| die;  
open (R3,"$file3.txt")|| die;   

 while (($lin1=<R1>) && ($line=<R2>) && ($line3= <R3>)){
  my $i;

stuck up here .. how to check weather a particular value of file 2 and file3 belongs to which and how many interval in the file1

Why do you get `8 c d file3`, when `d=23` in `file3` and the interval is `[30 40]` from `file1`? Shouldn't it only be `8 c file3`? — Håkon Hægland, May 03 '14 at 11:25
Why is interval 3 empty, when `a=9` from `file3` belongs to interval 3? — Håkon Hægland, May 03 '14 at 11:29
i tried to explain my logic of the programm and you have got it right can you help me with it — user3483833, May 03 '14 at 11:33
Sure, I can try to help you... So the output you show above is then not correct according to you input files? — Håkon Hægland, May 03 '14 at 11:46
i am not getting the right code for the correct output. can you plz tell me how to do it. — user3483833, May 03 '14 at 11:48
Can a given interval contain values from both `file2` and `file3`? In that case, how should the output look like? For instance, it could like this: `1 a file2 b file3` if both `a` from `file2` and `b` from `file3` is contained in interval 1. — Håkon Hægland, May 03 '14 at 11:51

Chris Charley · Answer 1 · 2014-05-08T18:50:01.777

Just another approach.

#!/usr/bin/perl
use strict;
use warnings;

open my $fh2, '<', 'file2' or die $!;
my %hash2 = map split, <$fh2>;
close $fh2 or die $!;

open my $fh3, '<', 'file3' or die $!;
my %hash3 = map split, <$fh3>;
close $fh3 or die $!;

open my $fh1, '<', 'file1' or die $!;
while (<$fh1>) {
    my ($id, $min, $max) = split;

    my @letters2 = grep $hash2{$_} >= $min && $hash2{$_} <= $max, 
        sort keys %hash2;
    my @letters3 = grep $hash3{$_} >= $min && $hash3{$_} <= $max, 
        sort keys %hash3;

    print join(" ", $id, @letters2,
                    @letters2 ? 'file2' : (),
                    @letters3,
                    @letters3 ? 'file3' : ()
               ), "\n";
}
close $fh1 or die $!;

This prints

1: a b file2
2: b c d file2
3: a file3
4: c d file2 a file3
5: b file3
6: b file3
7: d file3
8: c file3

Update: A better approach that would allow for more than 2 files

#!/usr/bin/perl
use strict;
use warnings;

my %name_num;
my @file = qw/file2 file3/;

for my $file (@file) {
    open my $fh, '<', $file or die $!;
    %{ $name_num{$file} } = map split, <$fh>;
}

open my $fh1, '<', 'file1' or die $!;
while (<$fh1>) {
    my ($id, $min, $max) = split;
    print $id;

    for my $file (@file) {
        my @letters =
            grep $name_num{$file}{$_} >= $min && $name_num{$file}{$_} <= $max, 
                sort keys %{$name_num{$file}};

        if (@letters) {
            print join(" ", '', @letters, $file);
        }
    }
    print "\n"; 
}
close $fh1 or die $!;

@"Håkon Hægland" Thanks Håkon – Chris Charley May 04 '14 at 01:30 — Chris Charley, May 04 '14 at 01:30

score 0 · Answer 2 · answered May 03 '14 at 12:42

You could try this perl script:

#! /usr/bin/perl

use v5.12;
use autodie;

my @files=qw(file2 file3);

my %val;

for my $file (@files) {
    open (my $fh, "<", $file);
    while (my $line=<$fh>) {
        my ($id, $val)=$line=~/(\S+)\s+(\d+)/;
        $val{$file}=[] if (! exists $val{$file});
        push (@{$val{$file}},{id=>$id, val=>$val});
    }
    close($fh);
}
my @iv;
open (my $fh, "<", "file1");
while (my $line=<$fh>) {
    my ($id,$start,$end)=$line=~/(\d+):\s+(\d+)\s+(\d+)/;
    my %h=();
    for my $file (@files) {
        my $str="";
        for my $vv (@{$val{$file}}) {
            my $v=$vv->{val};
            if ($v>=$start && $v<=$end) {
                $str=$str." ".$vv->{id};
            }
        }
        $h{$file}=$str if $str;
    }
    $h{id}=$id;
    push (@iv,\%h);
}
close($fh);

for (@iv) {
    my $int=$_;
    print $int->{id};
    for my $file (@files) {
        if (exists $int->{$file}) {
            print "\t",$int->{$file},"\t",$file;
        }
    }
    print "\n";
}

Output:

1    a b    file2
2    b c d  file2
3    a  file3
4    c d    file2    a  file3
5    b  file3
6    b  file3
7    d  file3
8    c  file3

@Borodin Thanks! I missed that.. I was thinking `use v5.12` would enable it implicitly, but it seems it only enables the `strict` pragma? — Håkon Hægland, May 03 '14 at 14:40
Effectively yes. I wrote a comment [**here**](http://stackoverflow.com/questions/23317796/cant-use-string-a-b-c-as-an-array-ref/23318196#comment35702183_23318196) that explains exactly what happens — Borodin, May 03 '14 at 15:11

perl code for checking for interval

2 Answers2