Qt .pro file: how to check if I'm compiling with MSVC 2013 toolset?

Question

I've tried this condition, but it doesn't work. How to check for MSVC 2013?

win32-msvc2013*{
    QMAKE_CXXFLAGS += /FS
}

I'm using Qt 5.3 Beta which has msvc-2013 mkspec.

@vahancho: Both Qt 4 and Qt 5, but if the solution only works with Qt 5 - that's fine. — Violet Giraffe, Apr 30 '14 at 07:28
@VioletGiraffe, yes, because in Qt 4.x `win32-msvc2013` is not defined in `mkspecs` directory. Maybe you can copy it from your Qt5 installation? — vahancho, Apr 30 '14 at 07:34
@vahancho: I'm using Qt 5 built with 2013 atm. If Qt4 doesn't support 2013 out of the box, then I don't care about it. — Violet Giraffe, Apr 30 '14 at 07:35
@VioletGiraffe, maybe I am wrong, but could you check whether this works: `win32-msvc2013 {`? Note the space between `3` and `{`. — vahancho, Apr 30 '14 at 07:50
@VioletGiraffe note that question it self from link I've given you shows alternative solution. — Marek R, Apr 30 '14 at 07:54
@vahancho: nope, no difference, doesn't work. I always write conditions without a space and never had a single problem. — Violet Giraffe, Apr 30 '14 at 07:56
@MarekR: it shows how to check variables, but I don't know which variable contains "2013". — Violet Giraffe, Apr 30 '14 at 07:56
First you should write what exactly you want distinguish: msvc vs gcc OR msvs2012 vs msvs2013? — Marek R, Apr 30 '14 at 08:06

score 17 · Accepted Answer · answered Mar 03 '16 at 01:12

Sorry for necroposting, but there seems no googleable solution. Seems I found one. There is vcvars.bat file, which is used for setting correct environment variables for VC. QtCreator, for example, use it while setting Tools -> Options -> Build & Run -> Compilers. Also it is used for MSVC Command Promt. Let`s check "VisualStudioVersion" env var in qmake (14.0 for MSVS 2015 in my case):

win32-msvc* {
    MSVC_VER = $$(VisualStudioVersion)
    equals(MSVC_VER, 14.0){
        message("msvc 2015")
    }
}

score 7 · Answer 2 · answered Apr 30 '14 at 08:28

7

Try this way:

win32-msvc* {
    system(cl|grep "Compiler Version 18.") {
        message( "msvc 2013 detected" )
        QMAKE_CXXFLAGS += /FS
    }
}

http://qt-project.org/doc/qt-4.8/qmake-function-reference.html

Can't test it I don't have Windows machine now.

answered Apr 30 '14 at 08:28

Marek R

32,568
6
55
140

Hm. Somehow the message is printed, but `/FS` is not added. How's that possible?.. If I write `QMAKE_CXXFLAGS += /FS` unconditionally, it is added. – Violet Giraffe Apr 30 '14 at 08:39
And sometimes when I run `qmake` I get "grep is not recognized as an external or internal command". Which is probably because Windows doesn't have `grep`. But sometimes it works. Very weird. – Violet Giraffe Apr 30 '14 at 08:41
you can try modify this solution by trying find another way to detect contents of standard output of `cl`. `grep` is natural way and it is present in widows for a long time, so ti is very strange that it doesn't works sometimes. – Marek R Apr 30 '14 at 09:12
1

There is no grep on windows, so this is not a good way to do this. Using $$(VisualStudioVersion) is a better solution. – Bill Hoffman Mar 08 '16 at 19:16
`find` is Winodws equivalent of `grep`. Anyway `$$(VisualStudioVersion)` is something new. – Marek R Mar 08 '16 at 22:23

score 5 · Answer 3 · answered May 19 '17 at 08:23

5

I use following:

contains(QMAKE_COMPILER_DEFINES, _MSC_VER=1800) { 
# MSVS2013
}

answered May 19 '17 at 08:23

Andrey

927
11
12

score 1 · Answer 4 · edited May 23 '17 at 11:54

1

Check supported platforms and table of Reference Configurations. There is no msvc2013! Newest visual studio supported is 2012.

So when detecting visual studio do not enforce 2013 sufix. Just use approach shown here

edited May 23 '17 at 11:54

Community

1
1

answered Apr 30 '14 at 08:01

Marek R

32,568
6
55
140

What approach? I need to add a certain flag for MSVC 2013, but not 2012 or 2010. This is not an answer. – Violet Giraffe Apr 30 '14 at 08:07
Qt 5.3 Beta, which I'm suing, supports msvc-2013. – Violet Giraffe Apr 30 '14 at 08:07
So correct your question. Instead downvoting me, write explicitly what you want distinguish and what version of Qt do you use. Link proves that msvs2013 is NOT SUPPORTED YET BY Qt. – Marek R Apr 30 '14 at 08:08
How is my question not correct? It asks how to check for MSVC **2013**. Not just any MSVC. – Violet Giraffe Apr 30 '14 at 08:10
5.3 Beta comes with `win32-msvc2013` mkspec. – Violet Giraffe Apr 30 '14 at 08:11
so write this in question. Note that in comments you have wrote about qt5 and qt4. – Marek R Apr 30 '14 at 08:12

Andrei R. · Answer 5 · 2017-09-12T04:14:12.557

0

found simple and elegant solution:

win32-msvc*: {
    COMPIL = $$find(CONFIG, "^win32-msvc*")
    COMPIL = $$replace(COMPIL,win32-,) # 'win32-msvc2017' -> 'msvc2017'
}

Edit: this only works with Qt 5.9.0 and later. Only then configs win32-msvc2012/win32-msvc2013/etc. are merged into single win32-msvc

edited Sep 12 '17 at 04:14

answered Sep 05 '17 at 08:37

Andrei R.

2,374
1
13
27

Qt .pro file: how to check if I'm compiling with MSVC 2013 toolset?

5 Answers5

Linked