How do you stop Arduino Esplora's tone function interfering with RGB LED

Question

On the Arduino Esplora, which is based on the Leonardo board, the PWM support of pin 5 which drives the Red component of the RGB LED looks like it shares a timer with the tone function. This has the unintended consequence of rendering the Red component useless after playing a tone as its behavior becomes unpredictable.

Here's a simple setup routine demonstrating the problem:

void setup()
{
    //analogWrite(5, 255);
    //delay(1000);
    analogWrite(5, 1);
    delay(2000);
    Esplora.tone(440);
    delay(1000);
    Esplora.noTone();
}

This turns on the Red channel of the LED to its lowest setting and holds it for two seconds, then plays a 440 HZ tone for 1/4 second, but as soon as the tone starts, instead of remaining on low brightness, the LED turns completely off.

If you uncomment the first two lines, this time when the tone starts, instead of (incorrectly) turning off as before, it now (equally incorrectly) turns back to full-brightness.

I can't figure out how to restore proper functionality of the Red component (or more specifically PWM on pin 5) after calling tone.

My guess is to generate the proper HZ for the sound, tone changes the settings for the timer, which then affects the PWM function. If I can find out how to manually reset the timer back to properly support PWM for the LED again, that may be the solution. However I'm new to Arduino, timers and the like so this is pure speculation and I could be completely wrong with this approach or my understanding of it, but from what I've read, this does seem to be leading in the right direction.

So anyone know how to restore proper PWM functionality on that pin?

Mark

Answer 1

Your suspicion regarding tone() reconfiguring the timer is correct. On the '32U4, timer 3 is used for tone(), but on the Esplora, OC3A is used for the red component (OC1B and OC1A are used for the green and blue components respectively). This means that every time tone() is called on the Esplora, timer 3 is reconfigured for CTC (WGM3[3:0]=0b0100), whereas the red component requires PWM in order to be used properly (and analogWrite() specifically uses 8-bit phase-correct PWM [WGM[3:0]=0b0001]). And since the timer is required until the tone stops, there's no sane way to switch it back and forth between modes.

Normally the easiest way to fix this is to tell tone() to use a different timer. Unfortunately on the Esplora there is no timer that it can use: timer 0 is used by delay() et al., timer 1 is used by the green and blue components, timer 4 works completely differently than the Arduino libraries are programmed for, and timer 2 doesn't even exist on the '32U4.

However, the pin for OC3A on the '32U4 is the same pin for nOC4A. This means that we may be able to use timer 4 to control the red component instead. The values for TCCR4* were not 0 when you examined them, but that may be because the bootloader fiddles with them; I was unable to find anything in the Arduino core or Esplora library that modifies them.

There are 2 issues with using timer 4:

1. Pin 13 is connected to OC4A. This means that pin 13 must always be configured as an input since the output from it will be a PWM signal that is the opposite phase as the red component.

2. The Arduino libraries are not programmed to handle timer 4. This means that we will need to access timer 4 at a low level to configure and use it.

And so:

pinMode(13, INPUT);
// disable timer 4 interrupts
TIMSK4 = 0;
// reset TCCR4C
TCCR4C = 0;
// set OCR4C to maximum
OCR4C=0xff;
// clear dead time register
DT4 = 0;
// enable PWM based on OCR4A and connect nOC4A (and OC4A)
TCCR4A = _BV(PWM4A) | _BV(COM4A0);
// match analogWrite() prescaling
TCCR4B = _BV(CS42) | _BV(CS41) | _BV(CS40);
// enable fast PWM
TCCR4D = 0;
// set minimum brightness
OCR4A = 0xff;

delay(1000);
OCR4A = 0xbf; // low brightness
delay(1000);
OCR4A = 0x3f; // high brightness
delay(1000);
OCR4A = 0x7f; // mid brightness
delay(1000);
OCR4A = 0x00; // max brightness

Answer 2

I studied the 32U4 docs a bit and grabbed the Esplora specific logic from the Arduino libraries that they use to init the PWM resources at startup. The resulting timerFix() routine below can be used to restore things to the proper settings.

void loop()
{
  Esplora.writeRGB(127,0,0);
  delay(1000);
  Esplora.tone(311);
  delay(1000);
  timerFix();
  Esplora.writeRGB(32,0,0);
  delay(1000);  
}
void timerFix()
{
  #define sbi(sfr,b) (_SFR_BYTE(sfr) |= _BV(b))

  //Tone will have hijacked the timer used for the 
  //RGB led RED channel so once we're done we need
  //to restore it.  First shutdown the tone internals
  //if not done already...
  Esplora.noTone();

  //Now clear the Timer Count Control Registers to
  //have them in a known state.
  TCCR3A = 0;
  TCCR3B = 0;

  //Setup the clock source - clk/64 
  sbi(TCCR3B, CS31);
  sbi(TCCR3B, CS30);

  //Set the wave form generator for 10-bit PWM
  sbi(TCCR3A, WGM30);

  //re-link the PWM timer to output channel
  //by passing something other than 0 and 255
  //so that the analogWrite function is forced to
  //recompute the correct value for either the
  //OCR3A or OCR3B register (output control register) 
  //as appropriate
  analogWrite(5, 1);

  //turn the LED channel off
  analogWrite(5, 0);
}