0

I am trying to understand if I can perform a query with Neo4j that contains both WITH and HAVING clauses. I have this so far:

MATCH (n)-[r:RELATIONSHIP*1..3]->(m) 
SET m:LABEL
WITH m
MATCH (m:LABEL)-[r2:RELATIONSHIP]->(q:OTHERLABEL)
WHERE r2.time<100
RETURN p,r2,q;

I'd now need to add in the same query something that in SQL would look 

MATCH (n)-[r:RELATIONSHIP*1..3]->(m)
SET m:LABEL
WITH m
MATCH (m:LABEL)-[r2:RELATIONSHIP]->(q:OTHERLABEL)
WHERE r2.time<100 
    AND WHERE count(q)=3
RETURN m,r2,q;

I know that Cypher doesn't let me use that without using something like the HAVING clause but when I try to add it to my query it conflicts with the previous WITH clause. Is this feasible or it is too nested that Cypher won't allow me to do it?

bobo32
  • 992
  • 2
  • 9
  • 21

2 Answers2

1

Not sure what your reference is for HAVING in cypher, but that's not the problem with the query.

  • drop the second WHERE - in cypher, you WHERE once and then you can expand that with all the binary fun you want
  • your first filter condition tests individual relationships (r2), but the second tests an aggregate (count(q)). You can't test a flat pattern and an aggregate from the same pattern at the same time
  • return things that you have actually bound (what is p?)

You may also want to change the second MATCH, m is already bound but you are re-matching it with the just created label. All in all, try something like

MATCH (n)-[r:RELATIONSHIP*1..3]->(m)
SET m:LABEL
WITH m
MATCH (m)-[r2:RELATIONSHIP]->(q:OTHERLABEL)
WHERE r2.time<100
WITH m, collect(r2) as rr, collect(q) as qq
WHERE length(qq) = 3
RETURN p,rr,qq;

for filtering first on flat relationship r2 then on size of aggregate, or for a flat WHERE .. AND .. try something like

MATCH (n)-[r:RELATIONSHIP*1..3]->(m)
SET m:LABEL
WITH m
MATCH (m)-[r2:RELATIONSHIP]->(q:OTHERLABEL)
WHERE r2.time<100 AND q.someProp = 10
RETURN m,r2,q;
jjaderberg
  • 9,844
  • 34
  • 34
  • - I used WHERE twice just to explain the sense of what I was doing. Sorry if I created confusion. - I corrected p, it had to be an m - Great answer. Thank you so much. I didn't need to filter on both r2 and q but now I know how to do it. – bobo32 Apr 08 '14 at 22:13
1

You can have as many with statements as you want, it is just piping query results from one part to the next. Actually WITH + WHERE = `HAVING``

MATCH (n)-[r:RELATIONSHIP*1..3]->(m)
SET m:LABEL
WITH m
MATCH (m:LABEL)-[r2:RELATIONSHIP]->(q:OTHERLABEL)
WHERE r2.time<100 
WITH m,collect([r2,q]) as paths
WHERE length(paths) = 3
RETURN m,paths;

Btw. I don't know where your p comes from.

Michael Hunger
  • 41,339
  • 3
  • 57
  • 80
  • sorry about the p, I corrected it now. I meant return m. – bobo32 Apr 08 '14 at 22:05
  • Does lenght(paths)=3 mean that Im returning all the nodes m which are connected to 3 nodes q through [r2:RELATIONSHIP] ? If so, I achieved my goal. Could you please confirm Michael? Thanks. – bobo32 Apr 08 '14 at 22:07