Unclassifiable statement in Fortran 95 when declaring function

Question

I would appreciate some help on this. The point of the program is to take a lower bound, an upper bound, and the number of steps, and then input them into the respective chosen equation to create a matrix that is the length of the steps, that contains the values for for the equation that was chosen. I'm getting an unclassifiable statement at:

array(i)=function1(x)
array(i)=function2(x)
array(i)=function3(x)

I feel like it has something to do with how I declared my function, but I cannot figure out a fix to it. Any help would be appreciated.

  PROGRAM stuff1
    IMPLICIT NONE

    !variables
      INTEGER::i,step
      REAL::lower,upper,function1,function2,function3,x,q,w,e
      CHARACTER(20)::option
      REAL,ALLOCATABLE::array(:)

    !formats
    101 FORMAT(A)     !single text element only
    102 FORMAT()      ! <description>

    !-------Variable Definitions-------!
    !
    !
    !
    !----------------------------------!

    !x= .1(upper-lower)

    !<Begin Coding Here>

    WRITE(*,101)"Hello User, please select a function to evaluate:"
    WRITE(*,101)
    WRITE(*,101)"A) f(x)=x^2+2x+4"
    WRITE(*,101)"B) f(x)=|x+4|"
    WRITE(*,101)"C) f(x)=sin(x)+42"
    WRITE(*,101)"Enter A,B,or C"

      DO
      READ(*,101)option
      IF ((option.EQ."A") .OR. (option.EQ."a")) THEN
      ELSE IF((option.EQ.'B') .OR. (option.EQ.'b'))THEN
      ELSE IF((option.EQ.'c') .OR. (option.EQ.'c'))THEN
      ELSE 
      WRITE(*,*)"Please enter A,B,or C"
      CYCLE
      END IF
      EXIT
      END DO

    WRITE(*,101)"please enter an lower bound:"

      READ(*,*)lower

    WRITE(*,101)
    WRITE(*,101)"please enter an upper bound:"
      READ(*,*)upper

    WRITE(*,101)
    WRITE(*,101)"please enter a step size"
      READ(*,*)step


    function1=((x**2)+(2*x)+4)
    function2=(abs(x+4))
    function3=(sin(x)+42)


    ALLOCATE(array(step))
    x=lower
    DO i=1,step
      IF ((option.EQ."A") .OR. (option.EQ."a")) THEN
          array(i)=function1(x)
      ELSE IF((option.EQ.'B') .OR. (option.EQ.'b'))THEN
          array(i)=function2(x)
      ELSE IF((option.EQ.'c') .OR. (option.EQ.'c'))THEN
          array(i)=function3(x)
      END IF
      x=x+(upper-lower)/step
    END DO

    DO i=1,step
      WRITE(*,'(4F6.2)')array(i)
    END DO

    END PROGRAM

score 4 · Answer 1 · answered Apr 01 '14 at 22:29

These lines

function1=((x**2)+(2*x)+4)
function2=(abs(x+4))
function3=(sin(x)+42)

appear to be three statement functions. This is an obsolescent feature which you should not use, instead you should define functions along the lines

   real function one(x)
       real, intent(in) :: x
       one = x**2 + 2*x + 4
   end function one

If you must program like it's 1979 then the correct form for a statement function would be

function1(x)=((x**2)+(2*x)+4)

You have omitted the dummy argument in the definitions, it's no surprise to me that the compiler gets angry and issues that error.

score 1 · Answer 2 · answered Apr 01 '14 at 22:26

1

That's not how to define a function in Fortran!

After the END PROGRAM, define your functions like:

real function function1(x)
  real,intent(in) :: x
  function1=((x**2)+(2*x)+4)
end function
real function function2(x)
  real,intent(in) :: x
  function2=(abs(x+4))
end function
real function function3(x)
  real,intent(in) :: x
  function3=(sin(x)+42)
end function

Or, even better, put them into a module!

answered Apr 01 '14 at 22:26

Alexander Vogt

17,879
13
52
68

Example of how to arrange module, subroutine or function and main program: http://stackoverflow.com/questions/6511711/computing-the-cross-product-of-two-vectors-in-fortran-90 – M. S. B. Apr 01 '14 at 23:53
I would say the most straightforward alternative of a statement function is an internal function. – Vladimir F Героям слава Apr 02 '14 at 07:19
@VladimirF I agree, but that would require additional changes to the code given by the OP. – Alexander Vogt Apr 02 '14 at 08:13
For clarity I suggest the syntax "end function foo" rather than just "end function" as used in the code above. – Fortranner Apr 02 '14 at 13:17
2

I do not, the functions are very short, you can look for the name two lines above. It is a pain to rename a function and then forget to rename the `end function`, so I recommend to use the name there only if the function does not fit a single screen. – Vladimir F Героям слава Apr 02 '14 at 14:42

Unclassifiable statement in Fortran 95 when declaring function

2 Answers2