ClientDataSet TBCDField rounding

Question

I'm using Delphi 5 + BDE + Oracle. I have the following function:

class function TClientDataSetFactory.GetClientDataSet(
      const qryGen: TDataSet): TClientDataSet;
    var
       dspDados: TDataSetProvider;
    begin
       Result := nil;
       try
          try
             Result := TClientDataSet.Create(nil);
             dspDados := TDataSetProvider.Create(Result);
             dspDados.DataSet := qryGen;
             qryGen.Active := True;
             qryGen.First;

             Result.Data := dspDados.Data;

             Result.First;
          except
             on E: Exception do
             begin
                raise;
             end;
          end;
       finally
       end;
    end;

so, when a run this:

var
   qryGen: TQuery;
   cdsGen: TClientDataSet;
begin
   qryGen := nil;
   try
      try
         qryGen := CriaQuery();
         qryGen.SQL.Text :=
            'SELECT SUM(TOTAL) AS TOTAL FROM MYTABLE';
         cdsGen :=  TClientDataSetFactory.GetClientDataSet(qryGen);
         ShowMessageFmt('Total: %f', [cdsGen.FieldByName('TOTAL').AsFloat]);
      except
         on E: Exception do
         begin
            raise;
         end;
      end;
   finally
      if Assigned(qryGen) then FreeAndNil(qryGen);
   end;
end;

i got "159,00" but, if i run this:

ShowMessageFmt('Total: %f', [qryGen.FieldByName('TOTAL').AsFloat]);

i got "159,25".

can someone help me?

Hmmm... perhaps you need to define the cdsGen "Total" field to be of type float (ftFloat) before running the query. — Michael Riley - AKA Gunny, Mar 31 '14 at 18:42
if i defina as ftFloat, i got type mismatch, expected Float and got BCD — Passella, Apr 02 '14 at 14:30

score 1 · Accepted Answer · answered Apr 25 '14 at 14:00

I solved the problem with another solution.

type
   TInternalQuery = class(TQuery)
   protected
      procedure InternalInitFieldDefs; override;
   public
      constructor Create(AOwner: TComponent; const qryGen: TQuery); reintroduce;
   end;

constructor TInternalQuery.Create(AOwner: TComponent; const qryGen: TQuery);
var
   intCont: Integer;
begin
   inherited Create(AOwner);
   Self.DatabaseName := qryGen.DatabaseName;
   Self.UpdateObject := qryGen.UpdateObject;

   Self.SQL.Text := qryGen.SQL.Text;

   for intCont := 0 to Self.ParamCount - 1 do
   begin
     Self.Params[intCont].Value := qryGen.Params[intCont].Value;
   end;  
end;

procedure TInternalQuery.InternalInitFieldDefs;
var
   intCont: Integer;
begin
   inherited InternalInitFieldDefs;
   for intCont := 0 to FieldDefs.Count - 1 do
   begin
      if (FieldDefs[intCont].Size = 0) and (FieldDefs[intCont].DataType = ftBCD) then
      begin
         FieldDefs[intCont].Precision := 64;
         FieldDefs[intCont].Size := 32;
      end;  
   end;  
end;

the problem is ((FieldDefs[intCont].Size = 0) and (FieldDefs[intCont].DataType = ftBCD)). when ClientDataSet is created, the field is truncated, because when oracle has a function like "SUM(TOTAL)" the result field is created with size 0, so the clientdataset handle the field as Integer field.

Tiago Nogueira · Answer 2 · 2014-03-13T21:24:09.503

0

Try with

ShowMessageFmt('Total: %n', [cdsGen.FieldByName('TOTAL').AsFloat])

or this

cdsGen := TClientDataSetFactory.GetClientDataSet(qryGen); **(cdsGen.FieldByName('Total') as TFloatField).DisplayFormat := '0.00';** ShowMessageFmt('Total: %f', [cdsGen.FieldByName('TOTAL').AsFloat])

edited Mar 13 '14 at 21:24

answered Mar 13 '14 at 18:49

Tiago Nogueira

316
2
10

the problem is the value, not the representation cdsGen.FieldByName('TOTAL').AsFloat = 159.00 and qryGen.FieldByName('TOTAL').AsFloat = 159.25 – Passella Mar 14 '14 at 16:36

ClientDataSet TBCDField rounding

2 Answers2

Linked