perl libXML crash when validating against XSD

Question

I'm migrating an app to the latest Debian and I get a strange server error when validating XML against a XSD

use strict;
use feature qw( :5.10.0 );

use XML::LibXML;

my $xsd = q{
<xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema">
  <xs:element name="shiporder">
    <xs:complexType>
      <xs:sequence>
        <xs:element name="orderperson" type="xs:string"/>
        <xs:element name="shipto">
          <xs:complexType>
            <xs:sequence>
              <xs:element name="name" type="xs:string"/>
            </xs:sequence>
          </xs:complexType>
        </xs:element>
      </xs:sequence>
      <xs:attribute name="orderid" type="xs:string" use="required"/>
    </xs:complexType>
  </xs:element>
</xs:schema>
};

my $soap=q{
<soap:Envelope
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xmlns:soapenc="http://schemas.xmlsoap.org/soap/encoding/"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema"
    soap:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/"
    xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
  <soap:Body>
    <shiporder
        orderid="889923"
        xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
        xsi:noNamespaceSchemaLocation="shiporder.xsd">
      <orderperson>John Smith</orderperson>
      <shipto>
        <name>Ola Nordmann</name>
      </shipto>
    </shiporder>
  </soap:Body>
</soap:Envelope>
};

my $xmlparser = XML::LibXML->new();
my $doc = $xmlparser->parse_string($soap);
my $nodelist = $doc->getElementsByTagNameNS('http://schemas.xmlsoap.org/soap/envelope/', 'Body');

say $nodelist->[0]->toString();

XML::LibXML::Schema->new(string => $xsd)->validate($nodelist->[0]);

which causes

* glibc detected perl: free(): invalid pointer: 0x0000000001cca220 ** ======= Backtrace: ========= /lib/x86_64-linux-gnu/libc.so.6(+0x76d76)[0x7fa0edd5fd76] /usr/lib/perl5/auto/XML/LibXML/LibXML.so(PmmREFCNT_dec+0xa3)[0x7fa0ed27c543] /usr/lib/perl5/auto/XML/LibXML/LibXML.so(XS_XML_LibXML_Node_DESTROY+0xeb)[0x7fa0ed260a4b] /usr/lib/libperl.so.5.14(Perl_pp_entersub+0x58c)[0x7fa0ee7ce70c] /usr/lib/libperl.so.5.14(Perl_runops_standard+0x16)[0x7fa0ee7c5ce6] /usr/lib/libperl.so.5.14(Perl_call_sv+0x45b)[0x7fa0ee7619db] /usr/lib/libperl.so.5.14(Perl_sv_clear+0x559)[0x7fa0ee7d4bd9] /usr/lib/libperl.so.5.14(Perl_sv_free2+0x52)[0x7fa0ee7d5292] /usr/lib/libperl.so.5.14(Perl_leave_scope+0x122f)[0x7fa0ee7fccef] /usr/lib/libperl.so.5.14(Perl_pp_leave+0xf2)[0x7fa0ee7cb112] /usr/lib/libperl.so.5.14(Perl_runops_standard+0x16)[0x7fa0ee7c5ce6] /usr/lib/libperl.so.5.14(perl_run+0x3a5)[0x7fa0ee767815] perl(main+0x149)[0x400f89] /lib/x86_64-linux-gnu/libc.so.6(__libc_start_main+0xfd)[0x7fa0edd07ead] perl[0x400fc1] ======= Memory map: ======== 00400000-00402000 r-xp 00000000 08:01 137813 /usr/bin/perl

and so on

I think it is failing when trying to free the memory allocated. I've tried cloning the objects but nothing seems to stop it. This is failing on a clean install of wheezy and jessie

You should [report this as a bug](https://metacpan.org/pod/XML::LibXML). I know the author, Shlomi will look into it. Alternatively, you can use [XML::Twig](https://metacpan.org/pod/XML::Twig). — Dan Dascalescu, Mar 03 '14 at 03:42
I reported it https://bitbucket.org/shlomif/perl-xml-libxml/issue/3/memory-crash-when-validating-xml-against . thanks for confirming I hadn't missed something obvious — KeepCalmAndCarryOn, Mar 03 '14 at 04:14

nwellnhof · Answer 1 · 2014-04-08T18:18:55.160

0

The validate method in XML::LibXML::Schema only works with whole documents. libxml2 also provides xmlSchemaValidateOneElement but there are no bindings for this function in XML::LibXML.

EDIT: This was fixed in XML::LibXML 2.0112. Now you can pass nodes to validate.

edited Apr 08 '14 at 18:18

answered Mar 03 '14 at 18:36

nwellnhof

32,319
7
89
113

KeepCalmAndCarryOn · Answer 2 · 2014-03-06T01:26:42.023

0

as @nwellnhof said in a separate answer, validate expects a document as a parameter, rather than a node

So I created a new document from the node and then it validates

my $xmlparser = XML::LibXML->new();
my $doc = $xmlparser->parse_string($soap);
my ($node) = $doc->findnodes('/soap:Envelope/soap:Body/*');

my $newDoc = XML::LibXML::Document->new("1.0");

$newDoc->setDocumentElement($node->cloneNode(1));
say $newDoc;

XML::LibXML::Schema->new(string => $xsd)->validate($newDoc);

edited Mar 06 '14 at 01:26

answered Mar 06 '14 at 00:30

KeepCalmAndCarryOn

8,817
2
32
47

If you need to add namespace attributes this is the approach `my $newDoc = XML::LibXML::Document->new("1.0"); my $newNode = $nodelist[0]->getChildrenByTagName('*')->shift()->cloneNode(1); $newNode->setAttribute("xmlns:xsd", "http://www.w3.org/2001/XMLSchema"); $newDoc->setDocumentElement($newNode);` – KeepCalmAndCarryOn Mar 11 '14 at 03:59

perl libXML crash when validating against XSD

2 Answers2