Output doesn't update when calling a cfc function

Question

Creating a ColdFusion function to handle the report outputs based on the varieties of 10 groupings. The output shows data grouping and amounts correctly, but it doesn't have correct report heading. For instance, it should have 5 different building names shown for each group, but all have the same building name.

Here is the code that calling the function:

<cfoutput query="Output" group="#Group1Field#" >
            <cfscript>
                Group1Count = 0;
                Group1Amount = 0;
            </cfscript>

            <h2>#eqInventoryHelper.getGroupingHeaderText(Group1, Output)#</h2></cfoutput>

Here is the code from the function:

<cffunction name="getGroupingHeaderText" output="false">
    <cfargument name="selectedGrouping" required="true" type="string"/>
    <cfargument name="outputQuery" required="true" type="query"/>
    <cfscript>
        var result = "";
        switch (arguments.selectedGrouping) {
            case "Building" :
            result = "Building: #arguments.outputQuery.building_code# - #arguments.outputQuery.building_name#";
            break;
            case "PI Name" :
                result = "PI: #arguments.outputQuery.pi_name#";
            break;
            case "Custodial Code" :
                result = "Custodial Code: #arguments.outputQuery.custodial_code# - #arguments.outputQuery.custodian_desc#";
            break;
            case "Manufacturer" :
                result = "Manufacturer: #arguments.outputQuery.manufacturer_name#";
            break;
            case "Room Number" :
                result = "Room Number: #arguments.outputQuery.building_room_number#";
            break;
            case "Current UC Fund" :
                result = "Current UC Fund : #arguments.outputQuery.cur_uc_fnd#";
            break;
            case "Original UC Fund" :
                result = "Original UC Fund: #arguments.outputQuery.orig_uc_fnd#";
            break;
            case "EFA Fund Source" :
                result = "EFA Fund Source: #arguments.outputQuery.efa_fnd_src_cd#";
            break;
            case "Asset Status" :
                result = "Asset Status: #arguments.outputQuery.asset_status_name#";
            break;
        }
        return result;
    </cfscript>
</cffunction>

Any suggestion?

Thanks.

When you do not loop over a query and refer to `queryName.columnName` you will get the value that is in the first row of the query. While you are looping over the query in outermost code, you are not doing so inside the function. Maybe you do not actually want to loop over the query when you call this particular method on this particular CFC? — Scott Stroz, Feb 24 '14 at 21:40
Where is the variable `Group1` set or is it a column in the query? Seems like `valueList()` might be what you need, but unsure since you did not explain the expected output. — Scott Stroz, Feb 24 '14 at 21:44
Scott Stroz, The code was written by another developer. I am fixing the issue now. I think it pass the query(output) to the method, so it doesn't need to use a specific queryName.columnName. Is this correct? The Group1 is defined in the beginning of the cfm, it was set to the grouping name. The output should be : Building 1000 - Education Building Total $100, Building 2000 - Engineering building total 200, Building 3000 - Science Building Total $300. But now I have the same building name for 3 groups. The calculation for the totals is correct, but the heading text is wrong. — tigerpuzzle, Feb 24 '14 at 22:50
You maybe just need to pass in the currentRow value to your function too, so you can then correctly reference the relevant row in your query. — duncan, Feb 25 '14 at 09:13
@duncan, thank you. Yes, I changed the code to pass the currentRow. It works. — tigerpuzzle, Feb 25 '14 at 17:47

score 0 · Answer 1 · answered Feb 25 '14 at 18:45

Assuming this is something like the code you implemented that worked for you, I'm posting this as an answer in case it's of benefit to anyone else in the future.

Simply pass in the current row value to the function so you can easily access that row in your query, something like:

<h2>#eqInventoryHelper.getGroupingHeaderText(Group1, Output, Output.currentRow)#</h2></cfoutput>

<cffunction name="getGroupingHeaderText" output="false">
    <cfargument name="selectedGrouping" required="true" type="string"/>
    <cfargument name="outputQuery" required="true" type="query"/>
    <cfargument name="whichRow" required="true" type="numeric"/>
    <cfscript>
        var result = "";
        switch (arguments.selectedGrouping) {
            case "Building" :
            result = "Building: #arguments.outputQuery.building_code[arguments.whichRow]# - #arguments.outputQuery.building_name[arguments.whichRow]#";
            break;

Output doesn't update when calling a cfc function

1 Answers1