How can I mark a call as "unsafe" with Carp?

Question

I have the same problem as in Can't disable stack trace in Carp::croak() for some reason. Because every call in the stack is considered "safe", croak() prints out a full stack trace every time. I'd like to disable that for certain calls.

Here's an example:

use Carp;

sub this_may_fail {
  # Some code...
  croak "This call failed!";
}

sub regular_code {
  this_may_fail();
}

regular_code();

Both subroutines are in the same package, so this_may_fail is automatically marked as safe. Is there any way to tell Carp that this_may_fail should be considered unsafe?

Is `regular_code()` the only thing calling `this_may_fail`? If so then you could just use a regular `die` — Zaid, Feb 18 '14 at 17:19
`this_may_fail` gets called from several different locations, and I need to know where it was called from so I can figure out what went wrong. — Jonathan, Feb 18 '14 at 18:39

ikegami · Accepted Answer · 2014-02-18T17:28:10.327

3

It's regular_code that's considered "safe" by this_may_fail. The check is based on namespace, so to make it unsafe, you'd place this_may_fail in a different namespace.

Or write your own croaker.

perl -e'
   use Carp qw( );
   sub untrusting_croak {
      goto &Carp::croak if $Carp::Verbose;
      my @caller = caller(1);
      die(join("", @_)." at $caller[1] line $caller[2]\n");
   }

   sub f { untrusting_croak("!!!"); }    # Line 9

   f();                                  # Line 11
'
!!! at -e line 11

edited Feb 18 '14 at 17:28

answered Feb 18 '14 at 17:18

ikegami

367,544
15
269
518

I ended up moving some of my functions to a different namespace. Thanks for your answer. – Jonathan Feb 27 '14 at 20:05

score 3 · Answer 2 · answered Feb 18 '14 at 17:41

Not especialy pretty, but, instead of this:

sub regular_code {
   ...;
   my $result = this_may_fail(@args);
}

You could use this...

sub regular_code {
   ...;
   my $result = do {
      my $sub = \&this_may_fail;
      package DUMMY; $sub->(@args)
   };
}

How can I mark a call as "unsafe" with Carp?

2 Answers2