FlowLayoutPanel remove background image and delete image file

Question

I am using the following code in order to delete all my controls inside a FlowLayoutPanel:

While FlowLayoutPanel1.Controls.Count > 0
    Dim controltoremove = FlowLayoutPanel1.Controls(0)
    FlowLayoutPanel1.Controls.Remove(controltoremove)
    controltoremove.Dispose()
    Application.DoEvents()
End While

This seems to work (as in i no longer see my controls inside my FlowLayoutPanel1 box) but once i get to this part of the code:

My.Computer.FileSystem.DeleteFile("C:\wamp\www\img\" & subitem("id").ToString.Replace("""", "") & ".jpg")

It tells me that the image is currently in use??? Since i disposed these controls (that have these images as backgroundimage) shouldn't i be able to delete the image file??

To create the buttons inside the FlowLayoutPanel i use this:

For Each subitem As JObject In item.Values
   Dim newPictureBox As New Button
   Dim Client As New WebClient

   strID = "http://graph.facebook.com/" & subitem("id").ToString.Replace("""", "") & "/picture?width=126&height=114"
   strName = subitem("name").ToString

   Client.DownloadFile(strID, "C:\wamp\www\img\" & subitem("id").ToString.Replace("""", "") & ".jpg")
   Client.Dispose()

   Dim bmp As New Bitmap(Image.FromFile("C:\wamp\www\img\" & subitem("id").ToString.Replace("""", "") & ".jpg"))
   newPictureBox.BackgroundImage = Image.FromFile("C:\wamp\www\img\" & subitem("id").ToString.Replace("""", "") & ".jpg")
   newPictureBox.Tag = subitem("id").ToString.Replace("""", "")
   newPictureBox.Name = "img" & intX
   newPictureBox.Width = bmp.Width.ToString()
   newPictureBox.Height = bmp.Height.ToString()
   FlowLayoutPanel1.Controls.Add(newPictureBox)
   AddHandler newPictureBox.Click, AddressOf newPictureBox_Click
   intX += 1
   imgDir.Add(strName, subitem("id").ToString.Replace("""", ""))
   bmp.Dispose()
Next

And it looks like the problem is the Dim newPictureBox As New Button. If i add

newPictureBox.dispose()

at the end of that code above it works with deleting the images from the directory... but is never displays the images inside the buttons to begin when if i do that :o/

What would I be doing incorrectly?

Have you tried FlowLayoutPanel1.Controls.Clear() this is preffered instead of looping through the controls. — Trevor, Feb 18 '14 at 02:56
Huh, then something else is up,what if you try to open it up not going through ur app — Trevor, Feb 18 '14 at 03:25
@MrCoDeXeR Check my updated OP - found the reason... just need to know how to correct it. — StealthRT, Feb 18 '14 at 03:32
Ahh i see, i see you are adding handlers, but where are you removing these at? Your using them but if you dont remove these they can have unhandled memory issues — Trevor, Feb 18 '14 at 03:40
You need to remove handlers that you created in this code, do it on .Dispose in the class your instantiating them — Trevor, Feb 18 '14 at 03:52
Doing **RemoveHandler newPictureBox.Click, AddressOf newPictureBox_Click** doesnt help the issue as well... — StealthRT, Feb 18 '14 at 04:02
let us [continue this discussion in chat](http://chat.stackoverflow.com/rooms/47716/discussion-between-mr-codexer-and-stealthrt) — Trevor, Feb 18 '14 at 04:13

Trevor · Accepted Answer · 2014-02-18T05:10:27.317

This will definitely work for you, sorry for the delay... Make sure you Import System.IO namespace as well... When you use the Image.FromFile(strFileName) method to create the Image, the method locks the file until you release the Image. Instead we can use FileStream to accomplish this task.

 For Each subitem As JObject In item.Values
  Dim newPictureBox As New Button
  Dim Client As New WebClient

  strID = "http://graph.facebook.com/" & subitem("id").ToString.Replace("""", "") & "/picture?width=126&height=114"
  strName = subitem("name").ToString

  Client.DownloadFile(strID, "C:\wamp\www\img\" & subitem("id").ToString.Replace("""", "") & ".jpg")
  Client.Dispose()

  Dim bmp As Bitmap
  Dim strPath As String = "C:\wamp\www\img\" & subitem("id").ToString.Replace("""", "") & ".jpg"

  Using fs As New FileStream(strPath, FileMode.Open, FileAccess.Read)
        Using b As New Bitmap(fs)
            bmp = New Bitmap(b.Width, b.Height, b.PixelFormat)
            Using g As Graphics = Graphics.FromImage(bmp)
                g.DrawImage(b, Point.Empty)
                g.Flush()
            End Using
        End Using
  End Using     

  newPictureBox.BackgroundImage = bmp
  newPictureBox.Tag = subitem("id").ToString.Replace("""", "")
  newPictureBox.Name = "img" & intX
  newPictureBox.Width = bmp.Width.ToString()
  newPictureBox.Height = bmp.Height.ToString()
  FlowLayoutPanel1.Controls.Add(newPictureBox)
  AddHandler newPictureBox.Click, AddressOf newPictureBox_Click
  intX += 1
  imgDir.Add(strName, subitem("id").ToString.Replace("""", ""))

 Next

:o( did not work either. It has to do with the **Dim newPictureBox As New Button**. — StealthRT, Feb 18 '14 at 04:20
its clearing the flow just fine.. its just leaving the newPictureBox for some reason. Thats what i need to get rid of. — StealthRT, Feb 18 '14 at 04:33
Please see the edit, it wasn't the buttons that you were creating rather how you were grabbing the images specifically. Please see updated answer. Also I have tried and tested this with deleting images as well :) — Trevor, Feb 18 '14 at 05:15

FlowLayoutPanel remove background image and delete image file

1 Answers1