How to FIX a value to the DBGrid's header heigth?

Question

When the user selects the header of my grid, I would like to bold the column header of the grid.
I use the following code to achieve this:

procedure TForm1.DBGrid1TitleClick(Column: TColumn);
var I: Integer;
begin
  //Prevent multiple clicks!  
  if fsBold in Column.Title.Font.Style then
    Exit;

  for I:= 0 to Column.Collection.Count-1 do
    (Column.Collection.Items[I] as TColumn)
            .Title.Font.Style := [];
  Column.Title.Font.Style := [fsBold];
end;

This code is working fine.

In the OnFormCreate I've defined the following header height:

type
  DBGridHack = class(TDBGrid);

procedure TForm1.FormCreate(Sender: TObject);
begin
  DBGridHack(DBGrid1).RowHeights[0] := 45;
end;

When I click in the Title, the procedure InternalLayout.MeasureTitleHeights changes the size back to the original. Thus, every time I change the font style I need to redefine the value for RowHeight[0].

The code would look like this:

procedure TForm1.DBGrid1TitleClick(Column: TColumn);
var I: Integer;
begin
  //Prevent multiple clicks!  
  if fsBold in Column.Title.Font.Style then
    Exit;

  for I:= 0 to Column.Collection.Count-1 do
    (Column.Collection.Items[I] as TColumn)
            .Title.Font.Style := [];
  Column.Title.Font.Style := [fsBold];

  //Every time!!
  DBGridHack(DBGrid1).RowHeights[0] := 45;
end;

There is another issue when the user redefine the Column's width, in this case the RowHeight[0] also returns to the original value. The only way I imagine to solve this, is to inherit DBGrid and override ColWidthsChanged, but how much more methods will I have to override?

Why this happens?
Is this a bug, or is my code bugged?
Is there a way to workaround this?

In a simple question.

How to FIX a value to the DBGrid's header heigth?

@SertacAkyuz Do you have an idea about how many events I'll have to override to make things work? — EProgrammerNotFound, Feb 11 '14 at 18:32
If you don't mind paying for one, DevExpress Quantumgrid is really good. But there are many free Grids out there... — whosrdaddy, Feb 11 '14 at 18:32
@Matheus - Not exactly. But doesn't look quite there yet with a quick browse; font change, anything that leads to columns update such as column index change.. — Sertac Akyuz, Feb 11 '14 at 18:37
A workaround could be to override Layoutchanged with an interposer class `procedure TDBGrid.LayoutChanged; begin inherited; if RowHeights[0]<>50 then RowHeights[0] := 50; end;` — bummi, Feb 12 '14 at 11:34
@bummi By looking into DBGrids.pas I can partially agree with you. There is a small problem: when the user calls `DBGrid1.Columns.RebuildColumns`, this is the only issue I can't solve by overriding `Layoutchanged`. — EProgrammerNotFound, Feb 12 '14 at 12:27
@Matheus - I can't really say so from here. Conceptually painting is for painting and it's generally a good idea to avoid anything that could trigger painting while painting. However you might have ran out of options and your solution might be working good, it's your call eventually. — Sertac Akyuz, Feb 12 '14 at 14:11
@SertacAkyuz Indeed. I cannot think about another solution. I guess the best option should be to change the component as whosrdaddy said — EProgrammerNotFound, Feb 12 '14 at 15:44

score 0 · Accepted Answer · answered Feb 12 '14 at 13:05

It seems like if I override the Paint procedure, it will work as expected. I don't know if there is side effects about this solution.

This is the code for the custom DBGrid. Please if this is not a good solution I would appreciate if you state it so.

TDBGrid1 = class(TDBGrid)
  private
    FTitleFixedHeight: Integer;
    function CheckHeaderFixed: Boolean;
  protected
    procedure Paint; override;
  public
    { Public declarations }
  published
    property TitleFixedHeight: Integer read FTitleFixedHeight write FTitleFixedHeight;
  end;

function TDBGrid1.CheckHeaderFixed: Boolean;
begin
  Result := (TitleFixedHeight <> 0) and (RowHeights[0] <> TitleFixedHeight);
end;

procedure TDBGrid1.Paint;
begin
  if CheckHeaderFixed then
  begin
    RowHeights[0] := TitleFixedHeight;
  end;    
  inherited;
end;

How to **FIX** a value to the DBGrid's header heigth?

1 Answers1

How to FIX a value to the DBGrid's header heigth?