Neo4j - NOT IN query

Question

The graph schema I have is (actors)-[:ACTED_IN]->(movies).

I know how to find actors who have worked with a particular actor as below:

MATCH (actor {name:"Tom Hanks"} )-[:ACTED_IN]->(movies)<-[:ACTED_IN]-(costars) return distinct costars;

I know how to find all the actors who have worked in some movie: MATCH (all_actor)-[:ACTED_IN]->(movies) return distinct all_actor;

However I don't know how to find all actors not in costars. How do I go about it?

You want to find all the actors (in the entire dataset) that have not starred in a movie with Tom Hanks? — Kenny Bastani, Jan 17 '14 at 13:23

score 22 · Accepted Answer · edited Jul 26 '17 at 16:24

22

As you want to deduct the coactors from the global list of actors this is not the best graph query, here are some suggestions.

// Max de Marzi
MATCH (actor:Actor {name:"Tom Hanks"})-[:ACTED_IN]->(movie), (other:Actor)
WHERE NOT (movie)<-[:ACTED_IN]-(other)
RETURN other

// Wes Freeman
MATCH (actor:Actor {name:"Tom Hanks"}), (other:Actor)
WHERE NOT (actor)-[:ACTED_IN]->()<-[:ACTED_IN]-(other)
RETURN other


// Michael Hunger
MATCH (actor:Actor {name:"Tom Hanks"} )-[:ACTED_IN]->(movies)<-[:ACTED_IN]-(coactor)
WITH collect(distinct coactor) as coactors
MATCH (actor:Actor)
WHERE NOT actor IN coactors
RETURN actor

edited Jul 26 '17 at 16:24

joe776

1,106
14
23

answered Jan 18 '14 at 00:45

Michael Hunger

41,339
3
57
80

NOT IN did not work for me. however using <> gave me the desired result – Jack Jan 18 '14 at 10:49
10

I think `WHERE NOT actor IN coactors` is right. Am I wrong? Your version doesn't work Michael – Gondil Apr 13 '15 at 13:44
4

`WHERE NOT thing IN list` worked for me too. Thanks @Gondil – Merrick Jun 27 '17 at 04:19
1

@michael-hunger `WHERE NOT thing IN list` works correct, but it's awful syntax. Why doesn't cypher not support `WHERE thing NOT IN list`, also? – Benjamin R Feb 13 '22 at 20:05

Neo4j - NOT IN query

1 Answers1

Linked