frameless windows with qt5 (qml)

Question

I spent some good hours on web searching but nothing help me..

I build GUI with QML and I want him without frame.

I tried to change my main.cpp like this:

#include <QtGui/QGuiApplication>
#include "qtquick2applicationviewer.h"

int main(int argc, char *argv[])
{
    QGuiApplication app(argc, argv);
    QtQuick2ApplicationViewer viewer;

    viewer.setMainQmlFile(QStringLiteral("qml/RR_QML/main.qml"));
    viewer.setFlags(Qt::FramelessWindowHint | Qt::Window);
    viewer.showExpanded();

    return app.exec();
}

I also tried to change main.qml file:

Window
{
    id: rootWindow
    flags: Qt.FramelessWindowHint | Qt.Window

    // my qml code here
}

but nothing work.

I'll glad for any help, thanks!

I work with:

Win 7 x64
Qt 5.1.1

Have you tried it with "native" QQuickView without the application viewer, just in case? — László Papp, Dec 31 '13 at 18:21
@LaszloPapp: I didn't try it yet. actually I newly in Qt, can you guide me please how to do this? thanks! — AsfK, Jan 01 '14 at 06:29
Does Qt's own frameless "shaped clock" example work as expected? http://qt-project.org/doc/qt-5.1/qtwidgets/widgets-shapedclock.html — timday, Jan 01 '14 at 12:05

score 22 · Accepted Answer · edited Jun 20 '20 at 09:12

This for example, works on Ubuntu:

import QtQuick 2.2
import QtQuick.Window 2.0
import QtQuick.Controls 1.1
import QtQuick.Controls.Styles 1.1

ApplicationWindow {
    id: backlight
    flags: Qt.FramelessWindowHint
    visible: true
    title: qsTr("backlight")
    width: 500
    height: 50
    x: (Screen.width - width) / 2
    y: (Screen.height - height) / 2
    color: "transparent"

    property real slideValue
    signal onSlide(real value)

    Rectangle {
        anchors.centerIn: parent
        width: parent.width
        height: 50
        color: "transparent"

        Rectangle {
            anchors.fill: parent
            radius: 25
            opacity: 0.3
            color: "gray"
        }

        Slider {
            anchors.centerIn: parent
            width: backlight.width - 16
            height: backlight.height
            value: backlight.slideValue
            focus: true
            onValueChanged: backlight.onSlide(value)
            Keys.onSpacePressed: Qt.quit()
            Keys.onEscapePressed: Qt.quit()

            style: SliderStyle {
                groove: Rectangle {
                    implicitHeight: 8
                    radius: 4
                    color: "gray"
                }
                handle: Rectangle {
                    anchors.centerIn: parent
                    color: control.pressed ? "white" : "lightgray"
                    border.color: "gray"
                    border.width: 2
                    width: 34
                    height: 34
                    radius: 17
                }
            }
        }
    }
}

It's an snippet from this project: https://github.com/oblitum/backlight/tree/cpp

Initially I was using Qt.SplashScreen | Qt.FramelessWindowHint but it didn't make a difference for me on Ubuntu (others also use Qt.SubWindow | Qt.Tool | Qt.FramelessWindowHint | Qt.WindowSystemMenuHint), so I left only Qt.FramelessWindowHint. It may make a difference for you.

This is Qt 5.2.

EDIT

Nevermind, Qt.SplashScreen did make a difference: no application icon is created.

I not success to run this, maybe becuase I using QT 5.0. I'll install Qt 5.2 and try again. Thank you very much! — AsfK, Jan 02 '14 at 06:45
Neither of the flags works for me. :( Win 7 x64, Qt 5.1.1, MinGW 4.8.0 — Qin Peixi, Jan 03 '14 at 12:16
it's work, but only with Qt 5.2. maybe them have bug on Qt 5.0.. so update your Qt to 5.2 and enjoy :) — AsfK, Jan 06 '14 at 06:33

frameless windows with qt5 (qml)

1 Answers1

EDIT