C# to VB.net Code conversion/translation

Question

I'm having a problem converting a particular code from C# to VB.
C# Code

const string filename = "C:\Sample.pdf";
PdfDocument document = PdfReader.Open(filename);

int imageCount = 0;
// Iterate pages
foreach (PdfPage page in document.Pages)
{
  // Get resources dictionary
  PdfDictionary resources = page.Elements.GetDictionary("/Resources");
  if (resources != null)
  {
    // Get external objects dictionary
    PdfDictionary xObjects = resources.Elements.GetDictionary("/XObject");
    if (xObjects != null)
    {
      ICollection<PdfItem> items = xObjects.Elements.Values;
      // Iterate references to external objects
      foreach (PdfItem item in items)
      {
        PdfReference reference = item as PdfReference;
        if (reference != null)
          {
            PdfDictionary xObject = reference.Value as PdfDictionary;
            // Is external object an image?
            if (xObject != null && xObject.Elements.GetString("/Subtype") == "/Image")
            {
              ExportImage(xObject, ref imageCount);
            }
          }
        }
      }
    }
  }

What I have done so far is:
VB Code

Dim filename As String = "C:\Sample.pdf"
Dim document As PdfDocument = PdfReader.Open(filename)
Dim imageCount As Integer = 0

For Each page In document.Pages
    Dim resources As PdfDictionary
    resources = page.Elements.GetDictionary("/Resources")
    If resources IsNot Nothing Then
        Dim xObjects As PdfDictionary
        xObjects = resources.Elements.GetDictionary("/XObject")
        If xObjects IsNot Nothing Then
            Dim items As ICollection(Of PdfItem) = xObjects.Elements.Values
            For Each item In items
                'Dim item As PdfReference
                Dim reference As PdfReference
                reference = item as PdfReference  
                ' ^^I dont know how to do this on VB

            Next
        End If
    End If
Next

So to summarize, this is the line of code that gives me problem converting:

C#

PdfReference reference = item as PdfReference;

VB.Net

Dim reference As PdfReference
reference = item as PdfReference // this gives me an error.

You can find your answer in the following SO question: http://stackoverflow.com/q/2450185/637425 — SynerCoder, Dec 10 '13 at 07:56
I guess that's it, it's not giving me an error anymore. Thanks :D How can i close this thread? — Codemunkeee, Dec 10 '13 at 07:58

score 1 · Answer 1 · answered Dec 10 '13 at 07:59

1

Do you have the correct imports statements and project references?

You might also just try a conversion tool like:

http://converter.telerik.com/

answered Dec 10 '13 at 07:59

Colin Pear

3,028
1
29
33

score 1 · Answer 2 · answered Dec 10 '13 at 07:59

you can use online language conversion tools language convertor

For Each page As PdfPage In document.Pages
    ' Get resources dictionary
    Dim resources As PdfDictionary = page.Elements.GetDictionary("/Resources")
    If resources IsNot Nothing Then
        ' Get external objects dictionary
        Dim xObjects As PdfDictionary = resources.Elements.GetDictionary("/XObject")
        If xObjects IsNot Nothing Then
            Dim items As ICollection(Of PdfItem) = xObjects.Elements.Values
            ' Iterate references to external objects
            For Each item As PdfItem In items
                Dim reference As PdfReference = TryCast(item, PdfReference)
                If reference IsNot Nothing Then
                    Dim xObject As PdfDictionary = TryCast(reference.Value, PdfDictionary)
                    ' Is external object an image?
                    If xObject IsNot Nothing AndAlso xObject.Elements.GetString("/Subtype") = "/Image" Then
                        ExportImage(xObject, imageCount)
                    End If
                End If
            Next
        End If
    End If
Next

Oh, sorry. It was a language convertor, thanks, Ill try it first — Codemunkeee, Dec 10 '13 at 08:01

score 0 · Answer 3 · answered Dec 10 '13 at 08:01

0

You can use http://converter.telerik.com/ to convert your code from c# to vb.net and back

answered Dec 10 '13 at 08:01

Andy

1

score 0 · Answer 4 · answered Dec 10 '13 at 08:01

0

This should work:

Dim reference as PdfReference = TryCast(item, PdfReference)

answered Dec 10 '13 at 08:01

Makita

726
5
12

If you're doing this, then you can do `Dim reference = TryCast(item, PdfReference)` – Zev Spitz Dec 10 '13 at 08:02

score 0 · Accepted Answer · edited May 23 '17 at 11:49

0

As is stated in this SO answer:

It is TryCast:

Dim x As String = TryCast(y, String)

Or in your case:

Dim reference As PdfReference 
reference = TryCast(item, PdfReference)

edited May 23 '17 at 11:49

Community

1
1

answered Dec 10 '13 at 08:02

SynerCoder

12,493
4
47
78

C# to VB.net Code conversion/translation

5 Answers5