Close userform with escape button

Question

I have 2 questions.

When I pressed esc button then close Userform1
When I input open in TextBox1 then Userform2 should show. Also clear TextBox1 in Userform1 automatically.

I have tried the below code:

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    If textbox1.value = "open" then
        userform2.show
        textbox1.value =""
    End If
End Sub

score 30 · Answer 1 · answered Dec 05 '14 at 20:10

30

Insert a new Command Button
Switch its Cancel property to True
You May Name it as cmdClose

Add next code:

Private Sub cmdClose_Click()

    Unload Me

End Sub

5.Set height and widht of the button to 0

that's it

answered Dec 05 '14 at 20:10

Jesus

8,456
4
28
40

2

Make sure, that the new button is the only button with property Cancel set to True. – Vityata Aug 31 '16 at 14:09
3

Consider also setting this button's `TabStop` property to `False` to remove the button from the keyboard's Tab cycle. – Alex Peters Apr 09 '18 at 06:12
1

I have no idea why this method should work but it does. :-) I add comments to the main answer. – jumpjack May 05 '20 at 08:25

Siddharth Rout · Answer 2 · 2013-11-27T11:30:19.740

21

Close userform1 with Esc

If you don't have any controls on userform then simply use this code

Private Sub UserForm_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    If KeyAscii = 27 Then Unload Me
End Sub

If you have say a TextBox and a Command Button then use this

Private Sub UserForm_Initialize()
    CommandButton1.Cancel = True
End Sub

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    If KeyAscii = 27 Then Unload Me
End Sub

Private Sub UserForm_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    If KeyAscii = 27 Then Unload Me
End Sub

Private Sub CommandButton1_Click()
    Unload Me
End Sub

If you have any other control that can take focus then you will have to use the KeyPress event of that control like I did for TextBox

when I input "open" to textbox1 then userform2 showed also clear textbox1 in userform1 automatically.

KeyPress will capture only one key. Use the Change event to compare what is there in the textbox.

Private Sub TextBox1_Change()
    If LCase(TextBox1.Value) = "open" Then
        TextBox1.Value = ""
        UserForm2.Show
    End If
End Sub

edited Nov 27 '13 at 11:30

answered Nov 27 '13 at 11:25

Siddharth Rout

147,039
17
206
250

3

Is there any way to achieve this without creating the KeyPress sub for every button that can take focus? I have a userform with quite a few controls on it and I'd like to be able to use Esc to unload the form at any point. – DukeSilver Apr 10 '18 at 18:07
Sorry I missed this comment... Yes create a control array. I have covered it on my [website](http://www.siddharthrout.com/index.php/2018/01/15/vba-control-arrays/) as well as stackoverflow. – Siddharth Rout Feb 12 '19 at 05:56
For some reason, nothing happens when I press the `Esc` key. Any suggestions?! – Karthick Ganesan Sep 13 '20 at 16:48
Which all controls do you have in the userform? @KarthickGanesan – Siddharth Rout Sep 13 '20 at 23:38
@SiddharthRout, a couple of labels and a Frame. – Karthick Ganesan Sep 14 '20 at 02:09
@KarthickGanesan Have you put `If KeyAscii = 27 Then Unload Me` in `Private Sub Frame1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)` as well? Change `Frame1` to the relevant frame – Siddharth Rout Sep 14 '20 at 06:41
1

Yikes, I missed that. Now it works! Thanks for your response! – Karthick Ganesan Sep 14 '20 at 13:42

score 1 · Answer 3 · answered Nov 13 '17 at 19:10

1

if you have a button the closes the form, just set the (Cancel) property to True and that will fire the cancel button on (Esc).. Cheers.

answered Nov 13 '17 at 19:10

Mahmoud Sayed

151
2
10

Close userform with escape button

3 Answers3

Linked

Related