3

I am using groovy and I have a collection :

  • person 1: age - 1, weight - 25
  • person 2: age - 2, weight - 20
  • person 3: age - 3, weight - 25

I need to find all persons whose age or weight is in the list of valid age/weight returned by a method called getValidAgeForSchool() or getValidWeightForSchool() ex. ages [2,3] or weight [20,25]

I know there is something like this (not working too)

persons.findAll{ it.age == 2 || it.weight == 20}

but how I can say (like the IN Clause)

persons.findAll {it.age in [2,3] || it.weight in [20,25]}.

I also tried this (ignoring the weight for now) but not returning the list when it is supposed to persons.age.findAll{ it == 2 || it == 3}

thanks.

tim_yates
  • 167,322
  • 27
  • 342
  • 338
user742102
  • 1,335
  • 8
  • 32
  • 51

1 Answers1

9

The code you have works:

def people = [
    [ id: 1, age: 1, weight: 25 ],
    [ id: 2, age: 2, weight: 20 ],
    [ id: 3, age: 3, weight: 25 ]
]

// This will find everyone (as everyone matches your criteria)
assert people.findAll {
           it.age in [ 2, 3 ] || it.weight in [ 20, 25 ]
       }.id == [ 1, 2, 3 ]

It also works if you have a list of instances like so:

class Person {
    int id
    int age
    int weight
}

def people = [
    new Person( id: 1, age: 1, weight: 25 ),
    new Person( id: 2, age: 2, weight: 20 ),
    new Person( id: 3, age: 3, weight: 25 )
]

I'm assuming your problem is that you have weight as a double or something?

If weight is a double, you'd need to do:

people.findAll { it.age in [ 2, 3 ] || it.weight in [ 20d, 25d ] }.id

But beware, this is doing double equality comparisons, so if you are doing any arithmetic on the weight, you may fall victim to rounding and accuracy errors

tim_yates
  • 167,322
  • 27
  • 342
  • 338
  • the weight is double and I typed the [20,25] as hard coded as is. I tried the code again and it's not giving me any result when it is supposed to. tnx – user742102 Nov 05 '13 at 15:13
  • @user742102 Added an example for where weight is a double, and a warning – tim_yates Nov 05 '13 at 15:17
  • okay. got it. you're right, I was comparing the same value but did not specify the type. The IN was actually just a guess, did not even know it exists. I read the entire documentation here -> http://groovy.codehaus.org/JN1015-Collections and I do not see a sample using it. it's working now. thanks :) – user742102 Nov 05 '13 at 15:22