Delphi change item background in listbox when double clicked

Question

I would like to be able to change item's background to red when they are double clikced and make them stay that color so I can do something with only the red ones on FormClose for instance.(ex: OnClose delete only the red items) Is that possible with standard component?

Answer 1

You need to owner-draw the ListBox. Set its Style property to either lbOwnerDraw, lbOwnerDrawVariable, or lbVirtualOwnerDraw, and then use its OnDrawItem event to draw the items however you want (in the case of lbOwnerDrawVariable, you will also have to provide an OnMeasureItem event handler). You will have to keep track of which items have been double-clicked, and then you can draw those items differently than the other items. For example:

type
  MyItem = record
    Text: String;
    DblClicked: Boolean;
  end;

MyItems: array of MyItem;

var
  Item: MyItem;
begin
  SetLength(MyItems, ...);

  MyItems[0].Text := 'Item Text';
  MyItems[0].DblClicked := False;

  ...

  for Item in MyItems do
    ListBox1.Items.Add(Item.Text);
end;

procedure TForm1.ListBox1DblClick(Sender: TObject);
var
  Pos: DWORD;
  Pt: TPoint;
  Index: Integer;
begin
  Pos := GetMessagePos;
  Pt.X := Smallint(LOWORD(Pos));
  Pt.Y := Smallint(HIWORD(Pos));
  Index := ListBox1.ItemAtPos(ListBox1.ScreenToClient(Pt), True);
  if Index <> -1 then
  begin
    MyItems[Index].DblClicked := True;
    ListBox1.Invalidate;
  end;
end;

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer; Rect: TRect; State: TOwnerDrawState);
begin
  if MyItems[Index].DblClicked then
  begin
    ListBox1.Canvas.Brush.Color := clRed;
    ListBox1.Canvas.Font.Color := clWhite;
  end else
  begin
    ListBox1.Canvas.Brush.Color := ListBox1.Color;
    ListBox1.Canvas.Font.Color := ListBox1.Font.Color;
  end;
  ListBox1.Canvas.FillRect(Rect);
  ListBox1.Canvas.TextRect(Rect, Rect.Left + 2, Rect.Top + 2, MyItems[Index].Text);
end;