Clojure lazy-eval inside apply

Question

I'm trying to read in a file line by line and concatenate a new string to the end of each line. For testing I've done this:

(defn read-file
[filename]
(with-open [rdr (clojure.java.io/reader filename)]
  (doall (line-seq rdr))))

(apply str ["asdfasdf" (doall (take 1 (read-file filename)))])

If I just evaluate (take 1 (read-file filename)) in a repl, I get the first line of the file. However, when I try to evaluate what I did above, I get "asdfasdfclojure.lang.LazySeq@4be5d1db".

Can anyone explain how to forcefully evaluate take to get it to not return the lazy sequence?

Jared314 · Accepted Answer · 2013-10-10T18:03:32.213

1

The take function is lazy by design, so you may have to realize the values you want, using first, next, or nth, or operate on the entire seq with functions like apply, reduce, vec, or into.

In your case, it looks like you are trying to do the following:

(apply str ["asdfasdf" (apply str (take 1 (read-file filename)))])

Or:

(str "asdfasdf" (first (read-file filename)))

You can also realize the entire lazyseq using doall. Just keep in mind, a realized lazy seq is still a seq.

(realized? (take 1 (read-file filename))) ;; => false
(type (take 1 (read-file filename))) ;; => clojure.lang.LazySeq

(realized? (doall (take 1 (read-file filename)))) ;; => true
(type (doall (take 1 (read-file filename)))) ;; => clojure.lang.LazySeq

A better option would be to apply your transformations lazily, using something like map, and select the values you want from the resulting seq. (Like stream processing.)

(first (map #(str "prefix" % "suffix")
             (read-file filename)))

Note: map is lazy, so it will return an unrealized LazySeq.

edited Oct 10 '13 at 18:03

answered Oct 10 '13 at 15:23

Jared314

5,181
24
30

That works, thanks. I have to ask though, the docstring for doall says that it forces lazy evaluation of functions, however, when I do `(apply str ["asdfasdf" (doall (take 1 (read-file filename)))])` I still get lazyseq. Can you explain this? – Nick Oct 10 '13 at 16:31
A lazyseq can be realized without converting to another type. `doall` realizes the entire seq, but you still have to treat it like a seq. – Jared314 Oct 10 '13 at 16:39
Thanks that clears things up, I was thinking it was something like that, but understanding clojure's docstrings is a talent in and of itself I think :) – Nick Oct 10 '13 at 16:57

Clojure lazy-eval inside apply

1 Answers1