How to replace spaces with dashes of folder names (in bulk)

Question

How to replace spaces with dashes of several thousand folders in bulk in Windows server 2008?.

Currently:

My folder

All folders need to become:

My-folder

Thanks

score 3 · Accepted Answer · answered Oct 09 '13 at 01:18

3

This works here.

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /D /R %%i IN (*) DO (
    SET "n=%%~nxi"
    REN "%%i" "!n: =-!"
)

answered Oct 09 '13 at 01:18

foxidrive

40,353
10
53
68

LS_ᴅᴇᴠ · Answer 2 · 2013-10-09T08:10:05.897

0

Use this batch file:

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /D /R %%i IN (*.*) DO (
    SET "n=%%~nxi"
    SET n=!n: =-!
    IF NOT "!n!" == "%%~nxi" ECHO MOVE "%%~i" "%%~dpi!n!"
)

Check results and if everything looks OK, remove ECHO before MOVE.

EDIT: Interactive version:

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET k=
FOR /D /R %%i IN (*.*) DO (
    SET "n=%%~nxi"
    SET n=!n: =-!
    IF NOT "!n!" == "%%~nxi" (
        ECHO "%%~i" =^> "!n!"
        IF /I NOT "!k!"=="A" SET /P k=[Y]es/[N]o/[A]ll]/[C]ancel?
        IF /I "!k!"=="C" GOTO :END
        IF /I "!k!"=="Y" MOVE "%%~i" "%%~dpi!n!"
        IF /I "!k!"=="A" MOVE "%%~i" "%%~dpi!n!"
    )
)
:END
PAUSE

Test this batch. It will ask before any rename (unless you enter A), so you can preview command and check result.

edited Oct 09 '13 at 08:10

answered Oct 08 '13 at 15:17

LS_ᴅᴇᴠ

10,823
1
23
46

nothing happened i saved it in bat but still the folders have spaces – Tarek Ezzat Oct 08 '13 at 15:36
You're supposed to check bat output - Then, if all ok, remove ECHO before MOVE to make it work. As already explained in answer. – LS_ᴅᴇᴠ Oct 08 '13 at 15:57
here is the file i created using the code you gave me is doesn' – Tarek Ezzat Oct 08 '13 at 19:04
so sorry it doesn't do anything at all so could you please take a look at it and tell what should i do and what i'm doing wrong https://dl.dropboxusercontent.com/u/125658459/renamedash.bat – Tarek Ezzat Oct 08 '13 at 19:05
Ok, I tested in my machine and it worked fine. I added an interactive version to answer, check it. – LS_ᴅᴇᴠ Oct 09 '13 at 08:10

How to replace spaces with dashes of folder names (in bulk)

2 Answers2

Linked