Perl XML::Simple for parsing internal nodes

Question

I want to parse the XML file that I have here and print the id attribute of internal elements.

This is the XML file

<?xml version="1.0"?>
<!DOCTYPE test SYSTEM "http://www.kegg.jp/kegg/xml/KGML_v0.7.1_.dtd">
<test name="A" >
    <node id="11" name="test1" >
        <internal id="111" name="A111"/>
     </node>
    <node id="12" name="B">
        <internal id="121" name="B121"/>
        <internal id="122" name="B122"/>

     </node>
</test>

and here is the code, It fails when one one node has two internal properties

use strict;
use warnings;

use XML::Simple;
use Data::Dumper;

my $xml=new XML::Simple; 
my $doc=$xml->XMLin("test.xml",KeyAttr => ['id']);

print Dumper($doc);

foreach my $node ( sort  keys %{$doc->{node}} ) {
    print $doc->{node}->{$node}->{internal}->{id}."\n";
}

Here is how dumper looks like

$VAR1 = {
      'name' => 'test1',
      'node' => {
                '11' => {
                        'name' => 'A',
                        'internal' => {
                                      'name' => 'A111',
                                      'id' => '111'
                                    }
                      },
                '12' => {
                        'name' => 'B',
                        'internal' => {
                                      '122' => {
                                               'name' => 'B122'
                                             },
                                      '121' => {
                                               'name' => 'B121'
                                             }
                                    }
                      }
              }
    };

@mpapec then the result is 111 ,122 it basically omits one of the ids (when it is 2 ids ) — shaq, Oct 01 '13 at 14:38
There are a number of related posts on PerlMonks about how to parse Kegg XML files that may be helpful. For example, [Parsing and XML file](http://www.perlmonks.org/?node_id=989488), [Parsing XML use LibXML](http://www.perlmonks.org/?node_id=1043959), [Parsing with SAX an XML document with not Root Node](http://www.perlmonks.org/?node_id=165318). There are also some here on SO, for example, [Parsing xml files using XML::Rules perl](http://stackoverflow.com/questions/17609381/parsing-xml-files-using-xmlrules-perl). — SES, Oct 01 '13 at 14:44

ikegami · Accepted Answer · 2013-10-01T18:47:48.643

0

Add

ForceArray => [qw( node internal )]

Code:

my $doc = XMLin(\$xml,
   ForceArray => [qw( node internal )],
   KeyAttr    => [qw( id )],
);

print(Dumper($doc));

my $nodes = $doc->{node};
for my $node_key ( sort { $a <=> $b } keys %$nodes ) {
   my $node = $nodes->{$node_key};
   my $internals = $node->{internal};

   for my $internal_key ( sort { $a <=> $b } keys %$internals ) {
      print("$internal_key\n");

      # my $internal = $internals->{$internal_key};
      # print("$internal->{name}\n");
   }
}

edited Oct 01 '13 at 18:47

answered Oct 01 '13 at 14:23

ikegami

367,544
15
269
518

Well It did not help, May be I have to change the way I access to id "in array fashion" – shaq Oct 01 '13 at 14:30
It makes it always return a hash for `internal` instead of just some of the time. You have to change your code to iterate of that hash. See the update. – ikegami Oct 01 '13 at 15:03

score 0 · Answer 2 · edited Jun 20 '20 at 09:12

Code:

#!/usr/bin/perl -w
use strict;
use warnings;

use XML::Simple;
use Data::Dumper;

my $xml=new XML::Simple;
my $doc=$xml->XMLin(&get_str(),ForceArray => ['internal'],KeyAttr => 'id');
print Dumper($doc);
    
sub get_str {
  return qq#<?xml version="1.0"?>
<!DOCTYPE test SYSTEM "http://www.kegg.jp/kegg/xml/KGML_v0.7.1_.dtd">
<test name="A" >
    <node id="11" name="test1" >
        <internal id="111" name="A111"/>
     </node>
    <node id="12" name="B">
        <internal id="121" name="B121"/>
        <internal id="122" name="B122"/>

     </node>
</test>#;
}

Output:

$VAR1 = {
      'name' => 'A',
      'node' => {
                '11' => {
                        'name' => 'test1',
                        'internal' => {
                                      '111' => {
                                               'name' => 'A111'
                                             }
                                    }
                      },
                '12' => {
                        'name' => 'B',
                        'internal' => {
                                      '122' => {
                                               'name' => 'B122'
                                             },
                                      '121' => {
                                               'name' => 'B121'
                                             }
                                    }
                      }
              }
    };

Reason:

Note 1: The default value for 'KeyAttr' is ['name', 'key', 'id']. If you do not want folding on input or unfolding on output you must set this option to an empty list to disable the feature.

Note 2: If you wish to use this option, you should also enable the ForceArray option. Without 'ForceArray', a single nested element will be rolled up into a scalar rather than an array and therefore will not be folded (since only arrays get folded).

Perl XML::Simple for parsing internal nodes

2 Answers2