Regarding named pipes behaviour in tcl

Question

I have a question regarding named pipes in tcl.

First I created the pipe with mkfifo:

mkfifo foo

Then execute the following tcl script:

set fifo [open "foo" r] 
fconfigure $fifo -blocking 1 
proc read_fifo {} { 
    global fifo 
    puts "calling read_fifo" 
    gets $fifo x 
    puts "x is $x" 
} 
puts "before file event" 
fileevent $fifo readable read_fifo 
puts "after file event"

When i run the tcl script it waits for an event without outputting anything.

Then, when I write to the fifo:

echo "hello" > foo

Now, the tcl scripts prints out :

before file event 
after file event

Why is 'read_fifo' function call not getting triggered here ?

Could anyone help me in understanding this behaviour.

Johannes Kuhn · Accepted Answer · 2013-09-19T12:28:33.927

3

fileevent relies on the the eventloop, which you don't enter.
fileevent just tells Tcl to call read_fifo when it is readable.

If you want blocking IO, then just call gets. This blocks until an entire line has been read.

set fifo [open "foo" r] 
fconfigure $fifo -blocking 1 
gets $fifo x 
puts "x is $x"

If you do it event-driven, you need fileevent, use non-blocking IO and you have to enter the event-loop (e.g. with vwait forever).

set fifo [open "foo" r] 
fconfigure $fifo -blocking 0 
proc read_fifo {fifo} { 
    puts "calling read_fifo" 
    if {[gets $fifo x] < 0} {
        if {[eof $fifo]} {
           # Do some cleanup here.
           close $fifo
        }
    }
    puts "x is $x" 
} 
fileevent $fifo readable [list read_fifo $fifo]
vwait forever; #enter the eventloop

Don't mix event-driven with blocking IO. This does not really work.

Note that you don't have to call vwait in Tk, doing so would reenter the event-loop, which is considered bad practice.

edited Sep 19 '13 at 12:28

answered Sep 19 '13 at 11:49

Johannes Kuhn

14,778
4
49
73

1

Technically event-driven and blocking IO can work together. It's just that you're often going to be unsatisfied with the result. – Donal Fellows Sep 19 '13 at 12:54
If you use blocking IO in an event-driven application, no events will be served. For Tk the GUI becomes unresponsive, and eggdrop will get a ping timeout. – Johannes Kuhn Sep 19 '13 at 17:45
Ah, but wish (on Unix) uses blocking IO in an event-driven way anyway. It does so with the console, because it assumes (usually rightly!) that the console is producing input for it on a line-by-line basis. – Donal Fellows Sep 20 '13 at 08:16
@DonalFellows This is something I discovered recently too on windows. If I do `package require Tk; after 500 {puts {Eventloop running}}` in Tclsh it will trigger that event, but not without loading Tk. (I just don't know how that works.) – Johannes Kuhn Sep 20 '13 at 08:48

Regarding named pipes behaviour in tcl

1 Answers1