Run child process and capture output one line at a time

Question

I tried this code:

Local $foo = Run(@ComSpec & " /c dir", '', 0, 2)
Local $line
While 1
    $line = StdoutRead($foo)
    If @error Then ExitLoop
    $line = StringStripCR($line)
    If StringLen($line) > 0 Then ConsoleWrite("START" & $line & "END" & @CRLF)
WEnd

I expected to get one line at a time, but instead I get 2, 3 or 50 lines. Why does this happen?

[Related](https://stackoverflow.com/a/27663324/4157124). – user4157124 Apr 22 '18 at 15:21 — user4157124, Apr 22 '18 at 15:21

John Henckel · Accepted Answer · 2018-04-27T21:35:08.713

StdoutRead() doesn't split by line feed, it just returns chunks of data. The following code parses the data into lines:

Local $foo = Run(@ComSpec & " /c dir", '', 0, 2)
Local $line
Local $done = False
Local $buffer = ''
Local $lineEnd = 0
While True
    If Not $done Then $buffer &= StdoutRead($foo)
    $done = $done Or @error
    If $done And StringLen($buffer) == 0 Then ExitLoop
    $lineEnd = StringInStr($buffer, @LF)
    ; last line may be not LF terminated:
    If $done And $lineEnd == 0 Then $lineEnd = StringLen($buffer)
    If $lineEnd > 0 Then
        ; grab the line from the front of the buffer:
        $line = StringLeft($buffer, $lineEnd)
        $buffer = StringMid($buffer, $lineEnd + 1)

        ConsoleWrite("START" & $line & "END" & @CRLF)
    EndIf
WEnd

Run child process and capture output one line at a time

1 Answers1