change eol character via cmd

Question

i have a file file1in with unix eol, i have a script to do some editing in it, but the editing is done into output.txt and is renamed as file1and this changes the eol to windows/dos

the code is given

set uu=file1
set vv=file2

setlocal EnableDelayedExpansion
(for /F "delims=" %%a in (%uu%) do (
   set "line=%%a"
   if "!line:345=!" neq "!line!" (
      if "!line:123=!" neq "!line!" (
         if not defined flag (
            findstr "123" %vv% | findstr "345"
            set flag=true
         )
      ) else (
         echo !line!
      )
   ) else (
      echo !line!
   )
)) >output.txt 
del %uu% 
rename output.txt file1

any way to change it back or retain unix eol via cmd without user input?

have tried directly inputing into the file1, gives a 0 kb file tried type output.txt>file1 gave dos/win eol echoing anything other than a blank line echo.>file1 changed the eol char

using batch scripts. @endoro, dont really know, till now i just used notepad++ and changed EOL coversion to unix/osx format from windows/dos. — Nisham Mohammed, May 12 '13 at 12:55

score 2 · Answer 1 · answered May 12 '13 at 15:05

2

try this:

@echo off&setlocal enabledelayedexpansion
set "uu=file1"
set "vv=file2"
set LF=^


rem keep two empty lines between set LF and here
setlocal EnableDelayedExpansion
(for /F "delims=" %%a in (%uu%) do (
   set "line=%%a"
   if "!line:345=!" neq "!line!" (
      if "!line:123=!" neq "!line!" (
         if not defined flag (
            findstr "123" %vv% | findstr "345"
            set flag=true
         )
      ) else (
         <nul set/p"=!line!!LF!"
      )
   ) else (
      <nul set/p"=!line!!LF!"
   )
)) >output.txt 
type output.txt

answered May 12 '13 at 15:05

Endoro

37,015
8
50
63

nope, still dos format. when i click on show eol char, it shows set lf=^ CRLF not LF. even tried making it LF by using unix format still doenst work – Nisham Mohammed May 12 '13 at 16:33
No all lines get **only** `LF` on the end, look inside with a hex editor. Please note the two empty lines, if they aren't empty this **doesn't work**. – Endoro May 12 '13 at 16:50

foxidrive · Accepted Answer · 2013-05-12T14:30:28.850

1

Here's a solution:

@echo off
::Syntax: batchfile "file.txt" >"file2.txt"

:init
for /f %%c in ('copy /z "%~dpnx0" nul') do set cr=%%c
(set lf=^

)
del file.tmp 2>nul
for /f "delims=" %%i in ('findstr /n "^" "%~1"') do (
set "line=%%i"
setlocal enabledelayedexpansion
set "line=!line:*:=!!lf!"
echo(!line!
endlocal
)>>file.tmp
setlocal enabledelayedexpansion
findstr /v "!cr!!lf!" file.tmp
endlocal
del file.tmp 2>nul

edited May 12 '13 at 14:30

answered May 12 '13 at 13:35

foxidrive

40,353
10
53
68

aaand it cant run coz i have 64 bit :( – Nisham Mohammed May 12 '13 at 13:45
I edited the post above. My original text was as follows: Horst Schaeffer wrote `CRLF.COM` which has some smarts, if you have a `32 bit windows`. http://www.horstmuc.de/horst.htm – foxidrive May 12 '13 at 14:32
can you explain a bit more its working? btw in view, i clicked show symbols, and the lf variable is set as CRLF not LF – Nisham Mohammed May 12 '13 at 15:09
yes, i dont know where to replace the filenames either? sorry if i come out as noob – Nisham Mohammed May 12 '13 at 16:26
If you call the batch file dos2unix.bat then the command will be `dos2unix "filein.txt" >"fileout.txt"` – foxidrive May 12 '13 at 22:23

Magoo · Answer 3 · 2013-05-12T15:03:43.257

1

Using pure CMD I'd say unlikely.

GNU SED should be capable of this transformation though.

sed -b s/\r//g infile >outfile

edited May 12 '13 at 15:03

answered May 12 '13 at 13:57

Magoo

77,302
8
62
84

gnu sed is not portable, is it? if not any portable solutions? – Nisham Mohammed May 12 '13 at 14:13
copied the same line, but the eol is not changed – Nisham Mohammed May 12 '13 at 14:16
GnuSED can't do it. VBS should be able to open a file and write the lines with a LF and otherwise no line ending. – foxidrive May 12 '13 at 14:20
Hmm - revised command worked for me. What do you mean by "portable"? It's a freely-available utility. `GNU SED` is the DOS flavour. Ux has its own version. What platforms are you targeting that are likely to run CMD on which `GNU SED` can' run? – Magoo May 12 '13 at 15:06

change eol character via cmd

3 Answers3