how to read a .txt file from different server in classic asp?

Question

I´m reading a text file from my server as I should with the below, but I wonder how I can read a txt file from a different server? What do I need to do to get it working?

Set fs=Server.CreateObject("Scripting.FileSystemObject")
Set f=fs.OpenTextFile(Server.MapPath("files.txt"), 1)

do while f.AtEndOfStream = false
Response.Write(f.ReadLine)
Response.Write("<br>")
loop

f.Close
Set f=Nothing
Set fs=Nothing

So this is working as it should, but I want to change the files.txt to http://www.somedomain.com/files.txt

Any input appreciated, thanks!

Did you try with some other domain ? If so, what issues you faced ? — Shankar Narayana Damodaran, Apr 29 '13 at 08:57
[Read this](http://stackoverflow.com/questions/7695999/how-to-read-text-file-in-classic-asp) — hs.chandra, Apr 29 '13 at 08:59
@hs.chandra, He is able to read the text file through his code. He is asking how to open a remote file(which is not on his server). — Shankar Narayana Damodaran, Apr 29 '13 at 09:00
possible duplicate of [Making a HTTP request to API possible with VB/ASP classic?](http://stackoverflow.com/questions/2883444/making-a-http-request-to-api-possible-with-vb-asp-classic) — Quentin, Apr 29 '13 at 09:04
I only get "Bad file name or number" if I try to have the http... — Claes Gustavsson, Apr 29 '13 at 09:05
@ClaesGustavsson — Yes. You want to read a resource over HTTP. — Quentin, Apr 29 '13 at 09:58

score 2 · Accepted Answer · answered Apr 29 '13 at 09:30

Claes , try this and let us know.

<% Option Explicit %>
<%
Const REMOTE_FILE_URL="http://www.somedomain.com/files.txt"

Call ShowRemoteFile

Sub ShowRemoteFile
    Dim objXML, strContents, arrLines
    Dim x
    Set objXML=Server.CreateObject("Microsoft.XMLHTTP")

    'read text file...
    objXML.Open "GET", REMOTE_FILE_URL, False
    objXML.Send
    strContents=objXML.ResponseText
    Set objXML=Nothing

    'split into lines and read line by line...
    arrLines=Split(strContents, VBCrLf)
    For x=0 To UBound(arrLines)
        Response.Write(arrLines(x)&"<br />")
    Next
End Sub
%>

Shankar this works perfect. Reads all the lines and writes them out line by line. Thanks a lot! — Claes Gustavsson, Apr 29 '13 at 09:52

score 0 · Answer 2 · edited May 23 '17 at 11:43

0

Use this function to fetch the text data (taken from here):

Function GetTextFromUrl(url)

  Dim oXMLHTTP
  Dim strStatusTest

  Set oXMLHTTP = CreateObject("MSXML2.ServerXMLHTTP.3.0")

  oXMLHTTP.Open "GET", url, False
  oXMLHTTP.Send

  If oXMLHTTP.Status = 200 Then

    GetTextFromUrl = oXMLHTTP.responseText

  End If

End Function

Dim sResult : sResult = GetTextFromUrl("http://www.somedomain.com/files.txt")

edited May 23 '17 at 11:43

Community

1
1

answered Apr 29 '13 at 09:04

haim770

48,394
7
105
133

Thanks, haim770, yes this is simular to what I got working now. – Claes Gustavsson Apr 29 '13 at 09:19

how to read a .txt file from different server in classic asp?

2 Answers2