How can I prevent duplicates in prolog

Question

My multiple solution problem arises due to Prolog's backtracking looping through the goals. Whilst I understand that, technically, each solution provided is correct, it is not useful to me. Is there a method to remove duplicates?

Here is my code so far:

flight(london, paris).
flight(paris, amsterdam).
flight(amsterdam, rome).
flight(rome, paris).
flight(rome, rio_de_janeiro).
route_from(A,B) :-
  flight(A,B).
route_from(A,B) :-
  flight(A,R),
  route_from(R,B).

An example query is:

?- route_from(A, paris).
A = london ;
A = rome ;
A = london ;
A = london ;
A = london ;
A = london ;
A = london ;
A = london ;
A = london ;
etc.

Regards.

gusbro · Answer 1 · 2023-03-02T13:02:22.523

4

You have a bigger issue other than returning repeated solutions. Your program, as is, will loop indefinitely as there are loops in your graph.

To avoid loops you may maintain a list of visited cities:

route_from(A,B) :-
  route_from(A,B, []).

route_from(A,B, _) :-
  flight(A,B).
route_from(A,B, Visited) :-
  flight(A,R),
  \+ member(A, Visited),
  route_from(R,B, [A|Visited]).

Now, this won't prevent returning duplicates if there are more than one way to go to a city. You can use setof/3 to obtain every solution without duplicates upon backtracking:

route_from_without_duplicates(A,B):-
  setof(t, route_from(A,B), _).

edited Mar 02 '23 at 13:02

answered Apr 26 '13 at 18:58

gusbro

22,357
35
46

Thank you, what is the purpose of \+? – Danny Rancher Apr 26 '13 at 19:36
1

Its negation (it succeeds if what is called fails); in this example it means that `A` should't be a member of `Visited` – gusbro Apr 26 '13 at 19:43
1

`setof(t, route_from(A,B), _)` is more compact, less error prone and slightly more efficient. – false Mar 02 '23 at 11:24

score 1 · Answer 2 · answered Mar 02 '23 at 11:42

Using closure/3:

?- closure(flight,A,B).
   A = london, B = paris
;  A = london, B = amsterdam
;  A = london, B = rome
;  A = london, B = rio_de_janeiro
;  A = paris, B = amsterdam
;  A = paris, B = rome
;  A = paris, B = rio_de_janeiro
;  A = amsterdam, B = rome
;  A = amsterdam, B = paris
;  A = amsterdam, B = rio_de_janeiro
;  A = rome, B = paris
;  A = rome, B = amsterdam
;  A = rome, B = rio_de_janeiro
;  false.

Apparently, there are no redundancies, but just in case:

?- setof(t,closure(flight,A,B),_).
   A = amsterdam, B = paris
;  A = amsterdam, B = rio_de_janeiro
;  A = amsterdam, B = rome
;  A = london, B = amsterdam
;  A = london, B = paris
;  A = london, B = rio_de_janeiro
;  A = london, B = rome
;  A = paris, B = amsterdam
;  A = paris, B = rio_de_janeiro
;  A = paris, B = rome
;  A = rome, B = amsterdam
;  A = rome, B = paris
;  A = rome, B = rio_de_janeiro.

How can I prevent duplicates in prolog

2 Answers2

Linked