Parse any file type as XML

Question

I have the following code snippet in a Gradle script (the syntax is a combination of Groovy/Java):

File file = new File(filename) // Filename is being read from console
def content = file.getText()
Document document = DOMBuilder.parse(new StringReader(content), false, false)

The problem is, I'm trying to parse an XML file, but with a xconf extension (e.g. file.xconf). For some reason or another, when I try the code above, I get the following error message (in the console):

java.io.FileNotFoundException: <full_path>/file.dtd (No such file or directory)

The path is correct, but I noticed the extension is suddenly being changed to .dtd. I noticed in the file there's a reference to the .dtd version of that file, but I want the parser to ignore that (and stop validation, which is why the 2nd argument of DOMBuilder.parse() is false). Can I change this behavior to be able to succesfully parse the file?

Note: If possible, I would also like to be able to do the same with (any) other file extension.

Thanks in advance!

score 1 · Answer 1 · answered Apr 25 '13 at 08:34

1

The file.xconf xml must have defined DTD reference in the XML. Open the file and check.

The DOM parser by default validates XML against the DTD associated with the XML. If you not want to validate set the validation mode to false. Check the DomBuilder API.

Other option is to define the DTD path in XML so that its accessible from anywhere or you can register a resolver also. I forgot how to do that but you can lookup.

answered Apr 25 '13 at 08:34

Bhushan Bhangale

10,921
5
43
71

It does indeed define a DTD reference, but - as you can see in the question - the validation mode is already set to false. – Pieter VDE Apr 25 '13 at 08:36
Which implementation of DOMBuilder you are using? Seems even if validation is set to false it still tries to load DTD. I looked my code and found its EntityResolver. You can create your own resolver by implementing EntityResolver. – Bhushan Bhangale Apr 25 '13 at 08:48
I'm using `groovy.xml.DOMBuilder`. – Pieter VDE Apr 25 '13 at 08:53

score 1 · Accepted Answer · answered Apr 25 '13 at 08:56

1

Try this:

import groovy.xml.*
import org.w3c.dom.Document;
import org.xml.sax.InputSource;

Document parseWithoutDTD( Reader r, boolean validating=false, boolean namespaceAware=true ) {
  FactorySupport.createDocumentBuilderFactory().with { f ->
    f.namespaceAware = namespaceAware
    f.validating = validating
    f.setFeature("http://apache.org/xml/features/nonvalidating/load-external-dtd", false);
    f.newDocumentBuilder().with { db ->
      db.parse( new InputSource( r ) )
    }
  }
}

Document d = new File( filename ).withReader { r ->
  parseWithoutDTD( r )
}

answered Apr 25 '13 at 08:56

tim_yates

167,322
27
342
338

This is a side-question: I noticed with this example, namespaceAwareness is on. But how do I declare the namespace here? I have absolutely no idea. Can you do something like this: `f.declareNamespace(...)` and then add an extra parameter to the method? – Pieter VDE Apr 25 '13 at 10:47
You don't declare the namespace when parsing, it is declared in the XML document – tim_yates Apr 25 '13 at 10:48
So it recognizes the namespace automatically? Can I later on address it like `file.'namespace:tagname'.getTextContent()`? Many thanks for your help so far. – Pieter VDE Apr 25 '13 at 10:51
Apperently it does. Thank you for the namespace-proof code snippet! – Pieter VDE Apr 25 '13 at 11:01

score 0 · Answer 3 · answered Apr 25 '13 at 08:38

0

A DTD defines the rules for XML documents. If you follow these rules, the xml document is considered as "valid". If you want to ignore the DTD file (e.g. because it doesn't exist), set the validation mode of your parse to false.

answered Apr 25 '13 at 08:38

Philipp Sander

10,139
6
45
78

I know what DTD is, but thank you for taking the time to clarify. As commented on the previous answer, validation mode is already set to false (as can be seen in the question code). – Pieter VDE Apr 25 '13 at 08:40

Parse any file type as XML

3 Answers3