batch: get the name of the owner of a folder

Question

the only command that i know to get the owner of a folder in a batch script is:

dir %foldername% /q

this has two problems:

it shows in a list all foldername's content, so i've to read only the first row (which contains < DIR > and ".") or you've to run

dir %parent_of_foldername% /q | findstr "%foldername%"
if the owner have a long name (exemple:TrustedInstaller) this will be trimmed

here is my c:\

13/03/2013  18.33    <DIR>          NT SERVICE\TrustedInstaProgram Files

13/03/2013  18.33    <DIR>          NT SERVICE\TrustedInstaProgram Files (x86)

Then how can i get the owner's name of a folder in a batch script?

Endoro · Answer 1 · 2013-04-04T20:22:23.990

2

You can try this:

@echo off &setlocal
set "foldername=c:\temp"
set "owner="

for /f "tokens=3*" %%i in ('dir /q %foldername%^|findstr "<DIR>"') do if not defined owner set "owner=%%j"
echo %owner%

.. and the owner without the computer name:

@echo off &setlocal
set "foldername=c:\temp"
set "owner="

for /f "tokens=1*delims=\" %%i in ('dir /q %foldername%^|findstr "<DIR>"') do if not defined owner set "owner=%%j"
echo %owner%

And third method (returns the full name on my machine):

@echo off &setlocal
set "foldername=c:\temp"
set "owner="

for /f "tokens=2delims=\:" %%i in ('cacls "%foldername%" ^| find "%computername%"') do set "owner=%%i"
echo %owner%

edited Apr 04 '13 at 20:22

answered Apr 04 '13 at 20:08

Endoro

37,015
8
50
63

ok, this is a solution, and I knew it, but: 1) is very slow (dir. .. findstr ..) 2) in the case of an owner with a name greater than 23 characters does not work (for example, "NT SERVICE \ TrustedInsta" is truncated – CSG Apr 04 '13 at 20:16

score 0 · Answer 2 · answered Apr 04 '13 at 20:23

@ECHO OFF
SETLOCAL
SET "owner="
FOR /f "tokens=2delims=\" %%i IN ('dir /q "%~1"' ) DO IF NOT DEFINED owner CALL :setown %%i
ECHO owner of "%~1" is %owner%

GOTO :eof

:setown
SET owner=%*
:setownl
SET $2=%2
IF defined $2 shift&GOTO setownl
IF NOT "%1"=="." SET "owner="&GOTO :eof
SET owner=%owner:~0,-2%
GOTO :eof

is my solution. Works for me...

score 0 · Answer 3 · answered Apr 04 '13 at 21:04

Jesper Johansson, the author of http://msinfluentials.com/blogs/jesper/archive/2007/07/02/show-the-owner-of-a-file.aspx, laments that there is no built-in command besides dir /q but lists a few other command-line tools that could work.

SubInACL.exe
FileACL.exe (I couldn't find this one available anymore)

batch: get the name of the owner of a folder

3 Answers3