Dynamic array of hashes in Perl

Question

I have a CSV file like this:

name,email,salary
a,b@b.com,1000
d,e@e.com,2000

Now, I need to transform this to an array of hash-maps in Perl, so when I do something like:

table[1]{"email"}

it returns e@e.com.

The code I wrote is :

open(DATA, "<$file") or die "Cannot open the file\n";
    my @table;

    #fetch header line
    $line = <DATA>;
    my @header = split(',',$line);

    #fetch data tuples
    while($line = <DATA>)
    {
        my %map;
        my @row = split(',',$line);
        for($index = 0; $index <= $#header; $index++)
        {
            $map{"$header[$index]"} = $row[$index];
        }
        push(@table, %map);
    }
    close(DATA);

But I am not getting desired results.. Can u help?? Thanks in advance...

Use `Text::CSV` to parse a CSV file. – chepner Mar 25 '13 at 13:47 — chepner, Mar 25 '13 at 13:47

score 5 · Accepted Answer · answered Mar 25 '13 at 13:51

5

This line

push(@table, %map)

should be

push(@table, \%map)

You want table to be a list of hash references; your code adds each key and value in %map to the list as a separate element.

answered Mar 25 '13 at 13:51

chepner

497,756
71
530
681

1

"Reference", not "address". – Dave Cross Mar 25 '13 at 15:29
Hmm how are the two different? – Srikrishnan Suresh Mar 27 '13 at 10:28
The value of a reference might be an address, but it's not required to be; it's just an implementation detail. – chepner Mar 27 '13 at 12:35

score 4 · Answer 2 · answered Mar 25 '13 at 13:57

There is no need to reinvent the wheel here. You can do this with the Text::CSV module.

#!/usr/bin/perl

use strict;
use warnings;
use v5.16;
use Text::CSV;

my $csv = Text::CSV->new;
open my $fh, "<:encoding(utf8)", "data.csv" or die "data.csv: $!";
$csv->column_names( $csv->getline ($fh)  );
while (my $row = $csv->getline_hr ($fh)) {
    say $row->{email};
}

Dave Cross · Answer 3 · 2013-03-25T19:11:04.407

2

Something like this perhaps:

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

my @table;

chomp(my $header = <DATA>);
my @cols = split /,/, $header; # Should really use a real CSV parser here

while (<DATA>) {
  chomp;
  my %rec;
  @rec{@cols} = split /,/;
  push @table, \%rec;
}

say $table[1]{email};

__END__
name,email,salary
a,b@b.com,1000
d,e@e.com,2000

edited Mar 25 '13 at 19:11

answered Mar 25 '13 at 13:58

Dave Cross

68,119
3
51
97

Dynamic array of hashes in Perl

3 Answers3