How do you declare PHONY targets as default actions with shake?

Question

I'm in the process of converting a Makefile into a Shakefile, and I'm not sure how to handle PHONY make targets (clean, install, etc.). I tried something like:

main = shake shakeOptions $ do
  want ["install"]
  "install" *> \_ -> do
    need ["mytarget"]
    system' "ln" ["-s", "mytarget", "linkname"]

It succeeds at create the symlinks, but reports an error "Error, rule "install" failed to build file: install".

So, if not with the "want" action, how do I declare that the default target I want to run is a phony one?

score 5 · Accepted Answer · answered Mar 18 '13 at 08:53

5

In shake-0.10.1 and above you can use the phony function to write:

main = shake shakeOptions $ do
  want ["install"]
  phony "install" $ do
    need ["mytarget"]
    system' "ln" ["-s", "mytarget", "linkname"]

This should do exactly what you want, and does not require a fake file to be produced. In addition, you may want to use shakeArgs rather than shake so that the user can select install from the command line, or chose another target such as clean.

answered Mar 18 '13 at 08:53

Neil Mitchell

9,090
1
27
85

changing accepted answer to this one, since this is exactly what I wanted indeed. Thank you for the update. – Hudon Mar 18 '13 at 11:06

Neil Mitchell · Answer 2 · 2013-03-18T08:55:18.067

In shake-0.9 and below phony targets are a bit of a weak spot in Shake - you can do them, but they are a more verbose and manual than they should be. Here are a few options:

Have the install rule produce a file

As a very simple solution, just add writeFile' "install" "" at the bottom of the install rule. This produces a dummy file, but it will rerun every time mytarget changes. If you want it to run every time install is requested (like a phony would in make), just add alwaysRerun. If you can ignore the redundant file, this is the simplest solution, until there is first-class phony support.

Use action

You can write:

main = shake shakeOptions $ do
  action $ do
    need ["mytarget"]
    system' "ln" ["-s", "mytarget", "linkname"]

This declares an action that is run on every build. In reality you probably only want this to be run if install is on the command line, so you can do:

main = do
  args <- getArgs
  shake shakeOptions $ do
    when ("install" `elem` args) $ action $ do
      ... install code ...

Use shakeArguments

In the later versions of shake you can use the shakeArgsWith function to write:

main = shakeArgsWith shakeOptions [] $ \_ targets ->
  if "clean" `elem` targets then do
    removeFiles "_make" "//*"
    return Nothing
  else return $ Just $ do
    when ("install" `elem` targets) $ do
       ... install code ...
    ... other rules ...
    want $ delete "install" targets

This gives you full control over how the targets are processed, so you can do something far more powerful than phony targets, but its more work.

Thanks, I'll follow the first solution. I added `phony x f = x *> \o -> (alwaysRerun >> writeFile' x "" >> f o)` for now so that I can do `"install" 'phony' \_ -> do ...` — Hudon, Mar 17 '13 at 14:20
@Hudon, in shake-0.10 you can do a lot better - see my other answer (although this answer is still useful as the workarounds may be useful for other things). — Neil Mitchell, Mar 18 '13 at 08:56

How do you declare PHONY targets as default actions with shake?

2 Answers2