How to count number of occurrences of a certain char in string?

Question

How can I count the number of occurrences of a certain character in a string in Delphi?

For instance, assume that I have the following string and would like to count the number of commas in it:

S := '1,2,3';

Then I would like to obtain 2 as the result.

http://delphi.cjcsoft.net//viewthread.php?tid=43892 – Gabriel Nov 06 '17 at 11:15 — Gabriel, Nov 06 '17 at 11:15

Andreas Rejbrand · Accepted Answer · 2013-03-08T13:02:48.297

40

You can use this simple function:

function OccurrencesOfChar(const S: string; const C: char): integer;
var
  i: Integer;
begin
  result := 0;
  for i := 1 to Length(S) do
    if S[i] = C then
      inc(result);
end;

edited Mar 08 '13 at 13:02

answered Mar 08 '13 at 12:57

Andreas Rejbrand

105,602
8
282
384

Can't I do it in a single line? – Mar 08 '13 at 12:58
14

@NareshKumar: Yes, of course: `OccurrencesOfChar(myString, ',')` – Andreas Rejbrand Mar 08 '13 at 12:58
2

+1 but chr is a poor name since it already has meaning. I suggest C – David Heffernan Mar 08 '13 at 13:02

RobertFrank · Answer 2 · 2013-03-08T22:49:24.597

20

Even though an answer has already been accepted, I'm posting the more general function below because I find it so elegant. This solution is for counting the occurrences of a string rather than a character.

{ Returns a count of the number of occurences of SubText in Text }
function CountOccurences( const SubText: string;
                          const Text: string): Integer;
begin
  Result := Pos(SubText, Text); 
  if Result > 0 then
    Result := (Length(Text) - Length(StringReplace(Text, SubText, '', [rfReplaceAll]))) div  Length(subtext);
end;  { CountOccurences }

edited Mar 08 '13 at 22:49

answered Mar 08 '13 at 16:15

RobertFrank

7,332
11
53
99

1

Interesting point of view! Maybe you could simplify the first statement to `Result := Pos(SubText, Text); if Result > 0 then...` [+1] – TLama Mar 08 '13 at 19:07
That's beautiful Robert. – Sam Dec 18 '13 at 00:08
This is sick and beautiful :) Obviously it's not very efficient but the trick itself behind the code is something programming should be about! – dkellner Apr 20 '18 at 14:53
4

Cute, but I'd hate finding this in code. If you're reading someone's code and run into this, you have to stop and think about how it works, then check to see if it's right. Code Should Be Clear. Sorry, but I don't find this elegant. To me, elegant means concise and obviously correct with a small + for clever. – Guy Gordon Jun 13 '18 at 13:55
1

It is also significantly slower than a simple loop over the characters. – Andreas Rejbrand Nov 06 '19 at 11:48

score 18 · Answer 3 · answered Mar 08 '13 at 14:02

And for those who prefer the enumerator loop in modern Delphi versions (not any better than the accepted solution by Andreas, just an alternative solution):

function OccurrencesOfChar(const ContentString: string;
  const CharToCount: char): integer;
var
  C: Char;
begin
  result := 0;
  for C in ContentString do
    if C = CharToCount then
      Inc(result);
end;

Raul · Answer 4 · 2013-03-08T18:41:17.967

12

This one can do the work for if you're not handling large text

...

uses RegularExpressions;

...

function CountChar(const s: string; const c: char): integer;
begin
 Result:= TRegEx.Matches(s, c).Count
end;

edited Mar 08 '13 at 18:41

answered Mar 08 '13 at 14:52

Raul

656
5
17

1

Why wouldn't it be good on Delphi? Regular expressions are quite good at handling large text bodies. – Leonardo Herrera Mar 08 '13 at 19:54
It is rather an overkill... Probably many times slower than accepted solution. – m227 Aug 10 '23 at 09:50

score 2 · Answer 5 · answered Apr 03 '17 at 18:56

2

You can use the benefit of StringReplace function as:

function OccurencesOfChar(ContentString:string; CharToCount:char):integer;
begin
   Result:= Length(ContentString)-Length(StringReplace(ContentString, CharToCount,'', [rfReplaceAll, rfIgnoreCase]));
end;

answered Apr 03 '17 at 18:56

Marwan Almukh

201
3
12

Significantly slower than a simple loop over the characters, and (IMHO) slightly less easy to immediate see the correctness. – Andreas Rejbrand Nov 06 '19 at 11:55

Alieh S · Answer 6 · 2020-09-11T06:38:53.850

1

Simple solution and good performance (I wrote for Delphi 7, but should work for other versions as well):

function CountOccurences(const ASubString: string; const AString: string): Integer;
var
  iOffset: Integer;
  iSubStrLen: Integer;
begin
  Result := 0;

  if (ASubString = '') or (AString = '') then
    Exit;

  iOffset := 1;
  iSubStrLen := Length(ASubString);
  while (True) do
  begin
    iOffset := PosEx(ASubString, AString, iOffset);
    if (iOffset = 0) then
      Break;
    Inc(Result);
    Inc(iOffset, iSubStrLen);
  end;
end;

edited Sep 11 '20 at 06:38

answered Sep 10 '20 at 08:26

Alieh S

170
2
8

1

That Copy will make the loop slower. You can do without it if you use [System.Pos](http://docwiki.embarcadero.com/Libraries/en/System.Pos) or [AnsiStrings.PosEx](http://docwiki.embarcadero.com/Libraries/en/System.AnsiStrings.PosEx) with the offset option. – LU RD Sep 10 '20 at 09:32
Correct remark, thanks. Unfortunately in Delphi 7 the Pos function does not have an Offset parameter. – Alieh S Sep 10 '20 at 10:54
1

If you look in StrUtils, you will find the PosEx function in Delphi 7. – LU RD Sep 10 '20 at 12:38

score 0 · Answer 7 · answered Feb 10 '21 at 12:56

0

Ummm... Am I missing something? Why not just...

      kSepChar:=',';//to count commas
      bLen:=length(sLineToCheck);
      bCount:=0;//The numer of kSepChars seen so far.
      bPosn:=1;//First character in string is at position 1
      for bPosn:=1 to bLen do begin
         if sLineToCheck[bPosn]=kSepChar then inc(bCount);
         end;//

answered Feb 10 '21 at 12:56

wywtk-com

1

This is more or less identical to the accepted answer. – LU RD Feb 10 '21 at 15:55
1

LU RD... Ummm...You're quite right, of course it is. Sorry I missed its previous appearance here. (I've used forums for years, do have SOME idea. Apologies for missing that.) – wywtk-com Feb 11 '21 at 17:12

How to count number of occurrences of a certain char in string?

7 Answers7

Linked