Parameterized class and polymorphism

Question

I was wondering whether there is a better more direct way to make use of polymorphism for a set of classes generated from a parameterized class. The following system verilog code works. Is there a more elegant way ? EDIT: Can I implement something similar in C++ ?

`define OVERRIDE_PARAMETER_CPU parameter WIDTH=32 ;
`define OVERRIDE_PARAMETER_GFX parameter WIDTH=16 ;     

class Req #(parameter WIDTH=8);
    bit[WIDTH-1:0]  Address;
    virtual function Print;
        $display("Generic: %x[%0d]",Address,WIDTH);
    endfunction
endclass

typedef Req#(8) generic_req ;

class CPU_Req extends generic_req;  
    `OVERRIDE_PARAMETER_CPU
    function Print;
        $display("CPU: %x[%0d]",Address,WIDTH);
    endfunction
endclass

class GFX_Req extends generic_req;          
    `OVERRIDE_PARAMETER_GFX
    function Print;
        $display("GFX: %x[%0d]",Address,WIDTH);
    endfunction
endclass


program Test ;

    generic_req Req_Q[$],Temp,Generic_Req;    
    CPU_Req     C_Req;
    GFX_Req     G_Req;

    initial
    begin
        C_Req=new();
        G_Req=new();
        Generic_Req=new();
        C_Req.Address=32'h1234;
        G_Req.Address=32'hFF;
        Generic_Req.Address=32'h0;

        Req_Q.push_back(Generic_Req);
        Req_Q.push_back(C_Req);
        Req_Q.push_back(G_Req);

        while(Req_Q.size()!=0)
        begin
            Temp=Req_Q.pop_front();
            Temp.Print();
        end    
    end    
endprogram

works in what? This doesn't look like C++ to me but is tagged as such. — CashCow, Mar 05 '13 at 16:41
Edited: I was wondering whether C++ have support for treating parameterized classes like extended classes or is it plain wrong. — Jean, Mar 05 '13 at 16:48
I felt it more like a hack than a solution as it works around the fact that the language doesn't natively support polymorphism for parameterized classes. — Jean, Mar 05 '13 at 17:12
Did you found any implementation for system verilog parameterized class in c++? — Farhat Shahir, Oct 27 '21 at 12:45

score 1 · Answer 1 · answered Mar 08 '13 at 03:56

I did some change on your code. I am not sure if that's what you are looking for.

class Req #(parameter WIDTH=8);
   bit[WIDTH-1:0]  Address;
   virtual function void Print;
      $display("Generic: %x[%0d]",Address,WIDTH);
   endfunction
endclass

//class CPU_Req extends generic_req;  
class CPU_Req #(parameter WIDTH=16) extends Req#(WIDTH);
     function void Print;
        $display("CPU: %x[%0d]",Address,WIDTH);
     endfunction
endclass

class GFX_Req #(parameter WIDTH=24) extends Req#(WIDTH);          
     function void Print;
        $display("GFX: %x[%0d]",Address,WIDTH);
     endfunction
endclass


program Test ;

   Req            Generic_Req;
   CPU_Req #(32)  C_Req32;
   CPU_Req        C_Req16;
   GFX_Req #(128) G_Req128;

   initial
     begin
        C_Req32     = new();
        C_Req16     = new();
        G_Req128    = new();
        Generic_Req = new();

        C_Req32.Address  = 32'h12345678;
    C_Req16.Address  = 32'h12345678;
        G_Req128.Address = {2{64'h1234_5678_9ABC_DEF0}};
        Generic_Req.Address=32'h12345678;

    C_Req32.Print();
    C_Req16.Print();
    G_Req128.Print();
    Generic_Req.Print();

     end    
endprogram

Result:

# CPU: 12345678[32]
# CPU: 5678[16]
# GFX: 123456789abcdef0123456789abcdef0[128]
# Generic: 78[8]

CPU_Req32,C_Req16 and G_Req128 are not compatible with Req class even though they are all extended from same base class(with different parameters though) — Jean, Mar 28 '13 at 05:28

score 0 · Accepted Answer · answered Apr 18 '13 at 20:58

The following code works as intended.

class BaseReq;
   virtual function void Print;
      $display("Base:");
   endfunction
endclass

class Req #(parameter WIDTH=6) extends BaseReq;
   bit[WIDTH-1:0]  Address;
   function void Print;
      $display("Generic: %x[%0d][%0d]",Address,WIDTH,$bits(Address));
   endfunction
endclass

class CPU_Req #(parameter WIDTH=16) extends Req #(WIDTH);
     function void Print;
        $display("CPU: %x[%0d][%0d]",Address,WIDTH,$bits(Address));
     endfunction
endclass

class GFX_Req #(parameter WIDTH=24) extends Req #(WIDTH);          
     function void Print;
        $display("GFX: %x[%0d][%0d]",Address,WIDTH,$bits(Address));
     endfunction
endclass


program Test ;

   BaseReq        Req_Q[$],Temp;
   Req            Generic_Req;
   CPU_Req #(32)  C_Req32;
   CPU_Req        C_Req16;
   GFX_Req #(128) G_Req128;

   initial
     begin
        Generic_Req = new();
        C_Req32     = new();
        C_Req16     = new();
        G_Req128    = new();
        Generic_Req = new();

        Generic_Req.Address = 32'h12345678;
        C_Req32.Address     = 32'h12345678;
        C_Req16.Address     = 32'h12345678;
        G_Req128.Address    = {2{64'h1234_5678_9ABC_DEF0}};

        Req_Q.push_back(Generic_Req);
        Req_Q.push_back(C_Req32);
        Req_Q.push_back(C_Req16);
        Req_Q.push_back(G_Req128);

        while(Req_Q.size!=0)
        begin
            Temp=Req_Q.pop_front();
            Temp.Print();
        end
     end    
endprogram

Thanks for the answer. Do you know where to find reference/example about inheritance of parameterized classes? And why you don't use $cast to cast child objects back to parent objects and before put them into Req_Q? — TyL, May 20 '16 at 16:31

Parameterized class and polymorphism

2 Answers2