Read a file block by block

Question

I am using perl and want to read an external file with the following structure (full code at the end of the post):

servicestatus {
  parameter1 = abc
  parameter2 = abc
  parameter3 = abc
  }

servicecomment {
  parameter1 = def
  parameter2 = abc
  parameter3 = ghi
  }

those blocks are located in different parts of the file, the status block is in the upper while the comment-block is in the lower part. (each commentblock is related to a certain statusblock)

now i'm trying to scan the file line-by-line, so i'm encountering a statusblock at first, read a certain parameter (i.e. parameter2) and finally search the rest of the file for a commentblock that has an equal parameter.

the script i have written to solve this problem is extremely nested, in addition to that it only finds the first statusblock, its corresponding commentblock and then leaves the loop, although there is much more to find. any help considering this problem is welcomed!

Here is the full code

while ($line = <SF>) {
  if ($line =~ /servicestatus/) {
    while ($line = <SF>) {
      if ($line =~ /service_description/) {
        $service_desc = $line;
        while ($line = <SF>) {
          if ($line =~ /servicecomment/) {
            while ($line = <SF>) {
              if ($line =~ /service_description/) {
                $service_desc2 = $line;
                if ($service_desc eq $service_desc2) {
                  while ($line = <SF>) {
                    if ($line =~ /comment_id/) {
                      if ($line =~ m/(\d+)/) {
                        $comment_id = $1;
                        while ($line = <SF>) {
                          if ($line =~ /entry_time/) {
                            if ($line =~ m/(\d+)/) {
                              $entry_time = $1;
                              if ($entry_time < $time_oldest) {

                                # Kommando wird in die Commandpipe geladen
                                open(CP, ">>$o_commandpipe") or die("nagios.cmd not found");

                                # Befehl wird ausgegeben, External Command DEL_SVC_COMMENT wird ausgeführt
                                print {CP} "[$time_now] DEL_SVC_COMMENT;$comment_id;$time_now\n";
                                close(CP);
                                print("Comment $comment_id deleted.\n");
                              }
                            }
                          }
                        }
                      }
                    }
                  }
                }
              }
            }
          }
        }
      }
    }
  }
}

close SF;

for a better understanding: this script is for nagios (server monitoring tool) and should delete user-defined comments for certain services after a particular time.

thanks in advance!

score 2 · Accepted Answer · 2013-02-20T09:05:00.013

2

A couple of suggestions:

Nested loops are not an appropriate design for your problem. What you need is one loop that goes through the file, with logic inside it.
Will the comment block with the equal parameter always be after its corresponding service status block? If not, you also need to rethink the design of going through the file line by line.
Are the blocks always separated by blank lines, as in the example? If so, you could set $/ = "\n\n";. Then you could read the file block by block instead of line by line.

Here is an example of how you could do this, using a hash to keep track of the ones you want to delete. I use the assumption that all blocks are separated by blank lines, but if that is not true, you could easily adapt this to ikegami's method of going through the file.

use warnings;
use strict;

{
    my %delete_params;
    local $/ = "\n\n";
    while (<DATA>)
    {
        if (/^servicestatus/ and /parameter2 = (.*)/)
        {
            $delete_params{$1}++; #Delete comments with this parameter.
        }
        elsif (/^servicecomment/ and /parameter2 = (.*)/ and 
               exists $delete_params{$1})
        {
            next;   #Comment matched; do not print.
        }

        print $_;
    }   
}

__DATA__
servicestatus {
  parameter1 = abc
  parameter2 = abc
  parameter3 = abc
  }

servicestatus {
  parameter1 = abc
  parameter2 = xyz
  parameter3 = abc
  }

servicecomment {
  parameter1 = def
  parameter2 = abc
  parameter3 = ghi
  }

servicecomment {
  parameter1 = def
  parameter2 = xyz
  parameter3 = ghi
  }

servicecomment {
  parameter1 = def
  parameter2 = rrr
  parameter3 = ghi
  }

edited Feb 20 '13 at 09:05

answered Feb 20 '13 at 08:57

yes, the blocks are separated by blank lines. anyway, the commentblocks and the statusblocks are separated by a lot of other, script-unrelated blocks. (it's like 3 statusblocks - 5 other blocks - 3 commentblocks) – hurley Feb 20 '13 at 09:01
thank you, but as the status- and commentblocks are located in a dynamic file, how do i move them to the DATA-section? – hurley Feb 20 '13 at 09:10
@hurley, simply replace `` with `` in the above code to use the file that you already opened in your code. I only used `__DATA__` so that I could give a complete working example for the answer. – Feb 20 '13 at 09:18
i'm stuck. the parameter i'm searching for is called "service_description" and is found in servicestatus and servicecomment. by using this code (i've split it in two conditional statements for a better understanding - http://codepad.org/xP9cl4mF) there is no output. there should at least be the line "status_description = abcdefg" or just "abcdefg". do you have an idea? – hurley Feb 20 '13 at 09:58
@hurley, the code looks fine. Could you post a sample of data that is not working? – Feb 20 '13 at 10:01
http://codepad.org/4UVpG2zU - just two out of many blocks i've extracted from the original *.dat - file – hurley Feb 20 '13 at 10:04
thanks for your effort, i have solved it! there was just a whitespace before and after the equal sign, which isn't in the dat file. – hurley Feb 20 '13 at 10:20
@hurley, it is because there are no spaces between `servicedescription` and the value. Change your regex to this: `if (/service_description\s*=\s*(.*)/)`. That will match the value whether or not there is whitespace around the equals sign. – Feb 20 '13 at 10:21
Hoping these not are Nagios cfg files being parsed. As they don't use the equal sign to separate key/value pairs. Just one or more white space chars. Example: 'service_description check_ping' – Jim Black Mar 06 '13 at 06:06

score 1 · Answer 2 · answered Feb 20 '13 at 08:50

1

How about

my $file; { local $/; $file = <$fh>; }
while ($file =~ /^\s*(\S+)\s*\{([^}]*)\}/mg) {
   my $name  = $1;
   my $block = $2;
   ...
}

answered Feb 20 '13 at 08:50

ikegami

367,544
15
269
518

Read a file block by block

2 Answers2