Parse log containing hex character codes using awk or xxd or something

Question

i have a file that looks like this:

.
.
.
    15 02 2013 12:05:07 [DBG] vspd[3327]: VSP   0: RX 452B30303032340D
    15 02 2013 12:05:07 [DBG] vspd[3327]: VSP   0: WX 452B30303032340D

Sniffer log of serial port communication.

How can i automatically translate hex char codes to string?

I tried to use some thing like this:

cat vspd.log | awk -F'(RX|WX)[[:space:]]*' '{print $2}' | awk 'BEGIN { FS = "" }{for (i = 1; i < NF; i = i + 1) a=$i$i+1;printf "%s", a; print}' | xxd -r

But it gives only very partial success, i think i messed something with pipes.

The question is how can i convert

tail -f file.log | awk -F'(RX|WX)[[:space:]]*' '{print $2}'

Into something readable?

To be exact echo -e "\x45\x2B\x30\x30\x30\x32\x34\x0D" | awk '{printf "%s\n", $_}' where \x45\x2B\x30\x30\x30\x32\x34\x0D == 452B30303032340D... I got it i want ascii characters instead of their hex codes! Sorry for misunderstanding. — Maquefel, Feb 15 '13 at 08:26
Nope, sorry i wanted to convert last ASCII part of each line to string on fly. — Maquefel, Feb 15 '13 at 08:39

score 1 · Answer 1 · answered Feb 15 '13 at 08:32

1

Perl solution:

#!/usr/bin/perl
while (<>) {
    ($prefix, $hex) = /^(.*) (.*)$/;
    $hex =~ s/(..)/chr hex $1/ge;
    print "$prefix $hex\n";
}

Output:

15 02 2013 12:05:07 [DBG] vspd[3327]: VSP   0: RX E+00024
15 02 2013 12:05:07 [DBG] vspd[3327]: VSP   0: WX E+00024

Note: You might need to remove the final \x0D from the strings.

answered Feb 15 '13 at 08:32

choroba

231,213
25
204
289

It works for me. If no one comes with a awk solution i ll accept your answer. I ll need to rewite your function for use with tail :( . Don't know perl at all. – Maquefel Feb 15 '13 at 08:49

Thor · Accepted Answer · 2019-12-20T18:32:11.310

You can indeed get there with awk and xxd, here is an example:

<infile awk -F'(RX|WX)[[:space:]]*' '{ print $2 }' | xxd -p -r | awk 1 RS='\r'

Output:

E+00024
E+00024

Old answer

With GNU awk you can use strtonum() to convert the hexadecimals, e.g.:

function hex2str(n) {
  s = ""
  for(i=1; i<=length(n)-1; i+=2)
    s = s sprintf("%c", strtonum("0x" substr(n, i, 2)));
  return s
}

Then you could do the conversion like this:

{ $NF = hex2str($NF) }

Here's a complete example:

<infile awk ' 
  function hex2str(n) {
    s = ""
    for(i=1; i<=length(n)-1; i+=2)
      s = s sprintf("%c", strtonum("0x" substr(n, i, 2)));
    return s
  }

  { $NF = hex2str($NF) }

  1
'

Output:

15 02 2013 12:05:07 [DBG] vspd[3327]: VSP 0: RX E+00024
15 02 2013 12:05:07 [DBG] vspd[3327]: VSP 0: WX E+00024

This was very useful! I had to change `for(i=1; i<=length(n)-2; i+=2)` to `for(i=1; i<=length(n)-1; i+=2)` since it wasn't printing the last character in the hexadecimal string. — Rusty Lemur, Dec 20 '19 at 17:30

Parse log containing hex character codes using awk or xxd or something

2 Answers2

Old answer