Is it possible to use Inno Setup with cmake/cpack?

Question

I'm porting some of our projects at work over to cmake/cpack, and while our current stuff is using Inno Setup, there does not appear to be a built-in CPack generator for Inno Setup. It seems to be either zip files or NSIS. Are there any CPack generators out there which use Inno Setup (and if so, where can I find them)? And if not, is there another way to use Inno Setup with cmake other than writing a script to do it and have cmake run that for its package target?

Answer 1

The question is now over 10 years old, but there's great news for Inno setup users. Kitware recently released CMake 3.27, which now includes a generator for Inno Setup. https://cmake.org/cmake/help/latest/cpack_gen/innosetup.html

I edited my answer to include an example, below.

[MyProject]
 |- Make.bat
 |- [source]
     |- CMakeLists.txt
     |- [hello]
     |    |- hello.cpp
     |    |- CMakeLists.txt
     |- [installer] 
          |- CMakeLists.txt
          |- config.xml
          |- Copyright.txt
          |- InstallerIcon.ico
          |- InstallerIcon.bmp
          |- UninstallIco.ico

make.bat:

md build
cd build
del *.* /S /Q
cmake -G "Visual Studio 17 2022" . "../source" -A x64

rem Firing up Build......................
cmake --build . --config Release
cd..

rem Run CPack
cpack --config build/CPackConfig.cmake

./source.CMakeLists.txt:

cmake_minimum_required(VERSION 3.27)

project(HelloWorld)

add_subdirectory(Hello)
add_subdirectory(Installer)

./hello/hello.cpp:

#include <iostream>

int main ()
{
    std::cout << "hello world";
}

./hello/CMakeLists.txt

cmake_minimum_required(VERSION 3.27)
project(Hello)
add_executable(Hello hello.cpp)

./installer/CMakeLists.txt

cmake_minimum_required(VERSION 3.27)

# We tell CMake which files to add the program and the C++ runtime  
install(TARGETS Hello DESTINATION .) # Dot means we install directly in target folder, not a subfolder
set (CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_SKIP TRUE) # override default path of Microsoft libraries
include (InstallRequiredSystemLibraries)  # Install Microsoft runtime libraries    
install (PROGRAMS ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS} DESTINATION .)  # Override default folder for system libraries.
# Add other files too: installing a config file (just as example, real application will rather use %ProgramData% )
install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/Config.xml" DESTINATION .) # Dot sets directly in target folder.  

# Generic CPack settings
set(CPACK_PACKAGE_NAME Hello)               
set(CPACK_PACKAGE_VENDOR "My Name")
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Hello World Program")
set(CPACK_PACKAGE_INSTALL_DIRECTORY ${CPACK_PACKAGE_NAME})  # Name of subfolder under 'Program Files'
set(CPACK_PACKAGE_VERSION_MAJOR    ${PROJECT_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR    ${PROJECT_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH    ${PROJECT_VERSION_PATCH})
set(CPACK_VERBATIM_VARIABLES       TRUE)         # Ensure correct escaping - always set to true

#Set resources used by the Windows installer
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/Copyright.txt") # Location of license file
set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/InstallIcon.bmp") # Logo in installer window

#Start Menu Shortcuts: executable without .exe and text label
set(CPACK_PACKAGE_EXECUTABLES "Hello" "Hello World") 
set(CPACK_CREATE_DESKTOP_LINKS "Hello") # Desktop link
 
# Define which generator to use
if (WIN32)
    # Inno Setup is supported from CMake 3.27. 
    set(CPACK_GENERATOR  INNOSETUP)   
    set(CPACK_INNOSETUP_SETUP_UninstallDisplayIcon "${CMAKE_CURRENT_SOURCE_DIR}/UninstallIco.ico") 
    set(CPACK_INNOSETUP_SETUP_SetupIconFile "${CMAKE_CURRENT_SOURCE_DIR}/InstallerIcon.ico")
       
    #Executable that user can run at end of install. It refers CPACK_PACKAGE_EXECUTABLES above.
    set ( CPACK_INNOSETUP_RUN_EXECUTABLES "Hello") 
    
    # OPTIONAL: Set up custom script for Inno Setup. Your Pascal functions to add in [code] block  
    # set (CPACK_INNOSETUP_CODE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/codefile.iss")  
else()
    set(CPACK_GENERATOR  STGZ )
endif()

# This must always be after all CPACK\_\* variables are defined
include(CPack)  

The other files in the install folder should be self-evident: icons, license text and a config file, each with your own content as you see fit.