8

I keep reusing lambda expressions such as

\x -> (f x, g x)

where I apply the same input to two functions and encapsulate the result in a pair. I can write a function capturing this

combine :: (a -> b) -> (a -> c) -> a -> (b,c)
combine f g x = (f x, g x)

Now the above lambda expression is just combine f g. I have two questions.

  1. I'm interested to know if there is a standard library function that does this that I just can't find.
  2. Out of curiosity, I'd like to rewrite this function in point-free style, but I'm having a lot of trouble with it.
Will Ness
  • 70,110
  • 9
  • 98
  • 181
bshourd
  • 83
  • 3

3 Answers3

12

  1. Control.Arrow has the function (&&&) for this. It has a "more general" type, which unfortunately means that Hoogle doesn't find it (maybe this should be considered a bug in Hoogle?).

  2. You can usually figure this sort of thing automatically with pointfree, which lambdabot in #haskell has as a plugin.

For example:

<shachaf> @pl combine f g x = (f x, g x)
<lambdabot> combine = liftM2 (,)

Where liftM2 with the (r ->) instance of Monad has type (a -> b -> c) -> (r -> a) -> (r -> b) -> r -> c. Of course, there are many other ways of writing this point-free, depending on what primitives you allow.

shachaf
  • 8,890
  • 1
  • 33
  • 51
12

I'm interested to know if there is a standard library function that does this that I just can't find.

It's easy to miss because of the type class, but look at Control.Arrow. Plain Arrows can't be curried or applied, so the Arrow combinators are pointfree by necessity. If you specialize them to (->), you'll find the one you want is this:

(&&&) :: (Arrow a) => a b c -> a b c' -> a b (c, c')

There are other, similar functions, such as the equivalent operation for Either, which specialized to (->) looks like this:

(|||) :: (a -> c) -> (b -> c) -> Either a b -> c

Which is the same as either.

Out of curiosity, I'd like to rewrite this function in point-free style, but I'm having a lot of trouble with it.

Since you're duplicating an input, you need some way of doing that pointfree--the most common way is via the Applicative or Monad instance for (->), for example \f g -> (,) <$> f <*> g. This is essentially an implicit, inline Reader monad, and the argument being split up is the "environment" value. Using this approach, join f x becomes f x x, pure or return become const, fmap becomes (.), and (<*>) becomes the S combinator \f g x -> f x (g x).

C. A. McCann
  • 76,893
  • 19
  • 209
  • 302
  • 2
    Part of the reason the Control.Arrow functions are hard to miss is that Hoogle won't unify type variables with `->`, even if the kinds match, so [Hoogling for `(a -> b) -> (a -> c) -> a -> (b,c)`](http://www.haskell.org/hoogle/?q=(a+-%3E+b)+-%3E+(a+-%3E+c)+-%3E+a+-%3E+(b%2Cc)) fails to find `(&&&)`. ([Hoogling for `f a b -> f a c -> f a (b,c)`](http://www.haskell.org/hoogle/?q=f+a+b+-%3E+f+a+c+-%3E+f+a+(b%2Cc) works, as does (with a warning) [Hoogling for `(a ~> b) -> (a ~> c) -> (a ~> (b,c))`](http://www.haskell.org/hoogle/?hoogle=%28a+~%3E+b%29+-%3E+%28a+~%3E+c%29+-%3E+a+~%3E+%28b%2Cc%29)). – Antal Spector-Zabusky Jan 16 '13 at 06:30
  • 1
    Thank you both for this, this is exactly what I wanted to know. Thanks Antal for pointing out the `a ~> b` syntax for Hoogle, which I didn't know about. – bshourd Jan 16 '13 at 16:16
6

There are actually quite a few ways of doing this. The most common way is to use the (&&&) function from Control.Arrow:

f &&& g

However, often you have more functions or need to pass the result to another function, in which case it is much more convenient to use applicative style. Then

uncurry (+) . (f &&& g)

becomes

liftA2 (+) f g

As noted this can be used with more than one function:

liftA3 zip3 f g h
ertes
  • 4,430
  • 1
  • 18
  • 23