XQuery in BaseX: return avg value from the output of the mapping

Question

I am trying to manage the output of the map:get function in BaseX.

The mapping file looks as follows:

 <around>
   <point NR="51151">161</point>
   <point NR="31252">82</point>
   <point NR="54321">323</point>
   <point NR="54321">319</point>
   <point NR="54321">327</point>
 </around>

and represents some geographic points with the No. as attribute (NR) and the distance from the certain search point as value. There are some points which are present more than one time (as the point 54321 in the example above). This is content-related ok since these are "branches" of the point with the same No.

What I wand to get is the average from the distances if I lookup these NR's.

My query:

 let $c :=
      <around>
        <point NR="51151">161</point>
        <point NR="31252">82</point>
        <point NR="54321">323</point>
        <point NR="54321">319</point>
        <point NR="54321">327</point>
      </around>
 for $r in $c//point
 let $m := map { data($r/@NR) := $r/text() }
 return
 if ( map:contains($m, '54321'  ) ) then
 avg(map:get($m, '54321'))
 else
 ()

... returns 323 319 327 , thus ignores the "avg" though there is no syntax error message in BaseX.

How could I achieve the above? Many thanks in advance!

Francis Avila · Accepted Answer · 2013-01-04T17:30:16.483

A map associates one key with one value. What you are actually doing here is creating one single-entry map $m for every iteration of the for loop. Your code is exactly equivalent to this:

for $r in $c/point
return if ($r/@NR eq '54321') then avg($r/text()) else ()

If you are only looking up a single key, I recommend you not use a map at all and just do this, which is much simpler and faster:

return avg($c/point[@NR='54321'])

Even if you are looking up multiple keys a naive implementation that uses group by or distinct-values() may still be faster than a map if BaseX has a fresh attribute index on the document you are querying.

That said, to use a map you need to build up single new map using map:new and group by

let $c :=
      <around>
        <point NR="51151">161</point>
        <point NR="31252">82</point>
        <point NR="54321">323</point>
        <point NR="54321">319</point>
        <point NR="54321">327</point>
      </around>
let $m := map:new(
    for $r in $c/point
    let $key := $r/@NR, $value := $r/text()
    group by $key
    return map {$key := $value}
) 
return avg($m('54321'))

You can also do this using function reduction (the fold- functions) instead of group-by:

let $c :=
      <around>
        <point NR="51151">161</point>
        <point NR="31252">82</point>
        <point NR="54321">323</point>
        <point NR="54321">319</point>
        <point NR="54321">327</point>
      </around>
let $reducer := function($points as map(*), $point as item()) {
    map:new((
      $points, 
      map { $point/@NR := ($points($point/@NR), $point/text())}
    ))
}
let $m := fold-left($reducer, map{}, $c/point)
return avg($m('54321'))

Remember that in production code you need to generate the map once and then use your list of key lookups on it to have any hope of seeing a speed benefit from using a map.

If you are only doing this for one key, it is faster and clearer to just say `return avg($c/point[@NR='54321'])` instead of using a map. Otherwise you need to save the map between key lookups (i.e. outside a loop) to gain the advantage of building the map. — Francis Avila, Jan 04 '13 at 17:23
In fact this will be needed to update multiple xml-files (insert a tag according to the result of mapping). My query was just a minimal example :-) How could I save the map outside the loop? Thank you! — v_e, Jan 05 '13 at 11:31
`let $m := ([expression that generates the map]) for $k in $list-of-keys return $m($k)`. But please make sure your indexes are up to date on your target document and try a naive non-map implementation first. It may be faster than you think. — Francis Avila, Jan 05 '13 at 16:14
Thanks again! I will certainly try this. Perhaps I will have to ask another question then :-) — v_e, Jan 05 '13 at 19:45
It runs now perfectly (if I do not miss something :-) ) as follows: `let $c := doc('path_to_file') let $reducer := [your code here] let $m := [your code here] for $w in db:open('db_name') let $p = $w/Data/point/text() return if ($p and map:contains($m,$p) ) then insert code {avg($m($p))} into $w/Data else ()` Thank you! — v_e, Jan 06 '13 at 13:29

XQuery in BaseX: return avg value from the output of the mapping

1 Answers1