Does anybody know how to create a shortcut to attach a selected file to iMessage?

Question

I would like to be able to select an item on my desktop and type a shortcut to attach the selected item to a new message with the Messages app. I've tried to create one in system preferences/keyboard/keyboard shortcuts/Application Shortcuts under Finder.app typed "Share>Message" and it didn't work. I have a shortcut to "new email with selection" that I created with automator but Messages is not an option there. I also tried searching for an Applescript or terminal command for this so I could do it with a swipe gesture using Better Touch Tool. I spoke with an Apple senior advisor and he said he didn't know how to do it either and to post it on the forums.

If anyone knows how to make a shortcut for this action, please let me know.

update: I copied this from /System/Library/PrivateFrameworks/ShareKit.Framework/Versions/A/Plugins/Message s.sharingservice/Contents/MacOS

If anyone knows if this line can be turned into a .service with automator, Please let me know how to do/modify it.

Thanks

/System/Library/PrivateFrameworks/ShareKit.framework/Versions/A/PlugIns/Messages .sharingservice/Contents/MacOS/Messages ; exit; NAME-Mac:~ NAME$ /System/Library/PrivateFrameworks/ShareKit.framework/Versions/A/PlugIns/Message s.sharingservice/Contents/MacOS/Messages ; exit; -bash: /System/Library/PrivateFrameworks/ShareKit.framework/Versions/A/PlugIns/Message s.sharingservice/Contents/MacOS/Messages

-- 

delay 0.218623 set timeoutSeconds to 2.000000 set uiScript to "click image \"Test File\" of group 1 of scroll area 1 of application process \"Finder\"" my doWithTimeout( uiScript, timeoutSeconds )

-- Message delay 0.263641 set timeoutSeconds to 2.000000 set uiScript to "click menu item \"Message\" of menu 1 of menu item \"Share\" of menu 1 of group 1 of scroll area 1 of application process \"Finder\"" my doWithTimeout( uiScript, timeoutSeconds )

on doWithTimeout(uiScript, timeoutSeconds) set endDate to (current date) + timeoutSeconds repeat try run script "tell application \"System Events\" " & uiScript & " end tell" exit repeat on error errorMessage if ((current date) > endDate) then error "Can not " & uiScript end if end try end repeat end doWithTimeout

Answer 1

I cannot see how to get those to run.

You could setup an Automator Service with its input set to files and folders in"Finder"

and use this code in a Run Applescript Action.

It works But the main thing that was an issue was getting the correct buddy. I have set it so you can choose the one you want. More work could be done I expect to let you type a name and it returns the smaller list of matching names and handles.

on run {input, parameters}

    set buddieList to {}
    set splitter to "======"
    tell application "Messages"
        --set buddieList to {name of buddies, handle of buddies}
        repeat with i from 1 to number of items in buddies
            set this_item to item i of buddies
            copy (name of this_item as string) & splitter & handle of this_item as string to end of buddieList

        end repeat
    end tell


    set inputAlias to item 1 of input as alias

    set text_returned to item 1 of (choose from list buddieList with prompt "TO:" without multiple selections allowed and empty selection allowed)
    set theBuddy to (do shell script "echo  " & quoted form of text_returned & " | awk -F" & splitter & " '{print $2}'")
    tell application "Messages"
        set theBuddy to first buddy whose handle is theBuddy

        send inputAlias to theBuddy

    end tell

end run

**UPDATE.

In answer to your comments: I did not actually use the search field in the finder share. So it was nice to see it was actually structued the same way I structured my chooser. :-)

But it seems it is searching you contacts rather than the Buddy list.

So this new script uses a search of for contact names which contains any text you enter. And just like the real share. There is no guarantee that the persons number or email will be linked to iMessages their end.

Also note I put this together in a few minutes. So its not as tidy as it could be. but It gives you something to play with.

on run {input, parameters}

    set buddieList to {}
    set splitter to "======"
    tell application "Messages"
        activate
        display dialog "Name Contains.." default answer "" buttons {"Cancel", "OK"} default button 2
        copy the result as list to {text_returned, button_pressed}

    end tell
    tell application "Contacts"

        set buddies to people whose name contains text_returned

        repeat with a from 1 to number of items in buddies

            set this_name to name of item a of buddies
            set this_email to email of item a of buddies
            set this_phone to phone of item a of buddies
            repeat with e from 1 to number of items in this_email

                set this_email_item to item e of this_email
                if this_email_item is not {} then
                    copy (this_name) & splitter & value of this_email_item as string to end of buddieList
                end if
            end repeat

            repeat with e from 1 to number of items in this_phone

                set this_iphone_item to item e of this_phone
                if this_iphone_item is not {} then
                    copy (this_name) & splitter & value of this_iphone_item as string to end of buddieList
                end if
            end repeat

        end repeat
    end tell

    tell application "Messages" to set text_returned to item 1 of (choose from list buddieList with prompt "TO:" without multiple selections allowed and empty selection allowed)

    set inputAlias to item 1 of input as alias

    set theBuddy to (do shell script "echo  " & quoted form of text_returned & " | awk -F" & splitter & " '{print $2}'")
    tell application "Messages"
        try
            set findBuddy to first buddy whose handle is theBuddy


            send inputAlias to findBuddy
        on error
             display dialog "NO BUDDY Found with " & theBuddy
        end try
    end tell

end run

It is meant to be put into a Run Applescript Action in Automator. As a Service. Copy and paste it replacing all the default code.