Objects on stage are not initialized outside constructor

Question

Inside my Document Class I have assign to an array some objects that are placed on stage so I can call them later.

When I declare the array outside the constructor the objects haven't been created and the assign values are null unlike when I declare them inside constructor. Why is this happening?

How can I avoid this?Can I use a listener to track when objects are loaded?

First Case

package { 
   public class Document extends MovieClip {
       var obj:Array = [object1,object2];
       public function Document() {
          trace(obj[0]); // <-- null
       }
   }
}

Second Case

package { 
   public class Document extends MovieClip {
       public function Document() {
          var obj:Array = [object1,object2];
          trace(obj[0]); // <-- reference value
       }
   }
}

Answer 1

Global variables (i.e. the ones outside any method) are loaded prior to anything, after the constructor is called and before it is executed.

Use this code instead:

package { 
   public class Document extends MovieClip {
       var obj:Array;
       public function Document() {
          obj = [object1,object2];
          trace(obj[0]);
       }
   }
}

ADDENDUM:

Stage objects are initialized at the top of constructor code, like designer objects are in .net for example.

So, since global variables are initialized prior to the execution of constructor code, object1 and object2 are still null.

ADDENDUM 2:

You have the following sequence:

1. Constructor of class is called
2. Global variables are initialized (your obj array, and also object1/object2 variables, but not their value)
3. Designer (your graphics on the stage) objects are initialized (that is object1 = new Object1() is called)
4. Constructor code is executed

Stage objects are always automatically declared and initialized, unless you de-check Automatically declare stage instances in Advanced AS settings.

Answer 2

Declare the array outside, and stuff values inside the constructor.

public class Document extends MovieClip {
   var obj:Array;
    public function Document() {
      obj = [object1,object2];
      trace(obj[0]); // <-- reference value
   }
}

Whatever you write as initialized value is processed first, anything embedded in editor is second, the constructor code is third. So, when you refer assets by name in initialization code, they are yet uninitialized, so you receive nulls.

Whatever listeners you use will only get applied after the object will be available. init() and ADDED_TO_STAGE listeners are useful if you need stage reference to align your code-controlled asset to given stage dimensions. Before that happens, the stage reference is null.

Answer 3

Well this is kind of vague. Where are those objects instantiated? I would suggest making sure they are instantiated in you class:

package
{
    public class Document extends Sprite //I don't think you really need MovieClip
    {
        //alternatively to the method bellow you could use something like:
        //
        // private var object1 : Object = new Object();
        // private var object2 : Object = new Object();
        // public var obj : Array = [object1, object2];
        //
        // just make sure they are instantiated before they are used in the obj contructor

        public var obj : Array = [new Object(),new Object()]; //again here I would suggest using a vector if they are the same type

        public function Document()
        {
            trace(obj[0]);
        }
    }
}

If those objects are external to the class I would suggest passing them to the contructor like this:

package
{
    public class Document extends Sprite //I don't think you really need MovieClip
    {
        public var obj : Array = [null,null]; //again here I would suggest using a vector if they are the same type

        public function Document(o1:Object=null,o2:Object=null)
        {
            if (o1 != null)
                obj[0] = o1;
            if (o2 != null)
                obj[1] = o2;
            // 
            if (obj[0] != null)
                trace(obj[0]);
            else
                trace("Obj[0] is null");
        }
    }
}

[LATER EDIT] As to the reason this is happening is because at the time of the array initialization those 2 are null (they haven't been initialized yet)

[LATER EDIT2] OK - Document is the root class of the flash - good to know Like I said in my comments, even though on stage those 2 objects aren't instantiated until they are added to stage. for that I would suggest listening to the ADDED_TO_STAGE event. if you pass them outside constructor they will be null when the array is created since they haven't yet been added to stage/created(contrary to popular belief, even in Flash, objects don't simply exist)