3

I just want to do a simple find and replace for multiple strings. For example, I need to replace all "A1", "A2", "A3" with "system" and all "B1", "B2" with "ACC" and so on...

Does anyone know a good route to take? I'm just not sure how to get this started. Thanks for the help!

Community
  • 1
  • 1
user960358
  • 295
  • 3
  • 6
  • 14

1 Answers1

3

Update at bottom adressing Michael's comment re a better approach for many pattern replacements

If you record a simple macro using the manual Replace options from the Excel menu you will get code that you can tidy up to this

  1. The first option will update a cell in the ActiveSheet than contains "I am A1" to "I am System" - a part string match
  2. The second option will only update cells in the ActiveSheet that contains only "A1" to "Sytem" - ie a whole cell string match

code

Sub UpdatePartial()
With ActiveSheet.UsedRange
.Replace "A1", "System", xlPart
.Replace "A2", "System", xlPart
.Replace "A3", "System", xlPart
.Replace "B1", "ACC", xlPart
.Replace "B2", "ACC", xlPart
End With
End Sub

Sub UpdateWhole()
With ActiveSheet.UsedRange
.Replace "A1", "System", xlWhole
.Replace "A2", "System", xlWhole
.Replace "A3", "System", xlWhole
.Replace "B1", "ACC", xlWhole
.Replace "B2", "ACC", xlWhole
End With
End Sub

Update

The code below

  1. Uses a basic Timer to compare replacing all partial strings ranging from A1-A99 and B1-B99
  2. The two methods are
    • The Replace method above called 198 times (ie 2*99) in a loop
    • A RegExp \ variant array combo

On my testing the second method is faster for the 198 replacements on a 1,000,000 cell range.

Less replacements will improve the relative speed towards the Replace. More towards the RegExp More cells will also improve the relative speed towards the Replace. Less towards the RegExp

I didn't proceed with trying a Find method with later parsing of strings. As a hyrbrid type solution (find then parse ut wouldn't be competetive to a single replace or parse)

Timer

Sub MainCaller()
Dim dbTime As Double
Dim lngCnt As Long

dbTime = Timer()
For lngCnt = 1 To 99
Call UpdatePartial("A" & lngCnt, "System")
Call UpdatePartial("B" & lngCnt, "System")
Next lngCnt
Debug.Print Timer() - dbTime
dbTime = Timer()
Call RegexReplace("(A|B)[1-99]", "System")
Debug.Print Timer() - dbTime
End Sub

1) Replace Sub

Sub UpdatePartial(StrIn As String, StrOut As String)
ActiveSheet.UsedRange.Replace StrIn, StrOut, xlPart
End Sub

2) Regexp - Variant Array Sub

Sub RegexReplace(StrIn As String, StrOut As String)
    Dim rng1 As Range
    Dim rngArea As Range
    Dim lngRow As Long
    Dim lngCol As Long
    Dim lngCalc As Long
    Dim objReg As Object
    Dim X()


    'On Error Resume Next
    'Set rng1 = Application.InputBox("Select range for the replacement of leading zeros", "User select", Selection.Address, , , , , 8)
    'If rng1 Is Nothing Then Exit Sub
    'On Error GoTo 0

    ActiveSheet.UsedRange
    Set rng1 = ActiveSheet.UsedRange

    'See Patrick Matthews excellent article on using Regular Expressions with VBA
    Set objReg = CreateObject("vbscript.regexp")
    With objReg
    .Pattern = StrIn
    .ignorecase = False
    .Global = True
    End With

   'Speed up the code by turning off screenupdating and setting calculation to manual
   'Disable any code events that may occur when writing to cells
    With Application
        lngCalc = .Calculation
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
        .EnableEvents = False
    End With

    'Test each area in the user selected range

    'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on
    For Each rngArea In rng1.Areas
        'The most common outcome is used for the True outcome to optimise code speed
        If rngArea.Cells.Count > 1 Then
           'If there is more than once cell then set the variant array to the dimensions of the range area
           'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks
            X = rngArea.Value2
            For lngRow = 1 To rngArea.Rows.Count
                For lngCol = 1 To rngArea.Columns.Count
                    'replace the leading zeroes
                    X(lngRow, lngCol) = objReg.Replace(X(lngRow, lngCol), StrOut)
                Next lngCol
            Next lngRow
            'Dump the updated array back over the initial range
            rngArea.Value2 = X
        Else
            'caters for a single cell range area. No variant array required
            rngArea.Value = objReg.Replace(rngArea.Value, StrOut)
        End If
    Next rngArea

    'cleanup the Application settings
    With Application
        .ScreenUpdating = True
        .Calculation = lngCalc
        .EnableEvents = True
    End With

    Set objReg = Nothing
End Sub
brettdj
  • 54,857
  • 16
  • 114
  • 177
  • What if I only wanted to update this in one column? Would I use something like Columns("C:C") with activesheet? – user960358 Nov 07 '12 at 05:37
  • You can use `With ActiveSheet.Columns("A:A")` rather than `ActiveSheet.UsedRange`. BUT before running, you should set the Find and Replace option via the xl Menu to `worksheet` rather than `workbook` – brettdj Nov 07 '12 at 06:18
  • If you use Regex, you would only have to write two replace statements. Instead of A1, A2, A3, you would search for A[0-9]{1,2}. That will find A1-A99. Same with B: B[0-9]{1,2}. That way you don't have to keep writing replace statements in perpetuity if your data sets get larger/smaller. – tmoore82 Nov 07 '12 at 20:52
  • @tmoore82 except the OP didn't ask to match from A1-A99. Plus you can't actually use Regexp directly with a Excel VBA Replace. – brettdj Nov 07 '12 at 21:25
  • @brettdj I guess I made the assumption that "and so on" meant "A1... A(n)." Not necessarily a safe assumption. :) While Excel doesn't incorporate Regexp directly into its F&R, MS has made it pretty accessible nonetheless. [link](http://support.microsoft.com/kb/818802/en-us) But I've seen a lot of your posts here, and I defer to you. Do you think Regexp would make sense if it were A1:A99? Or would it make more sense to use a loop that combined A with a counter? – tmoore82 Nov 07 '12 at 22:09
  • @tmoore82 Yes. I agree with you that for hundreds of pattern based replacements a new approach would probably be needed. :) For example a `Find` and `FindNext` to locate all potential replacement strings, followed by a `Like` test (Regexp probably overkill given the pattern simplicity) for would be a good option. The option would depend on how many matches may be found. Alternatively dumping the UsedRange into a variant array and using a Regexp might make more sense. – brettdj Nov 07 '12 at 22:50
  • @tmoore82 new sample codes added. Regexp looks a winner for singe shot changes making many replacements – brettdj Nov 07 '12 at 23:39
  • 1
    @brettdj Awesome stuff! Really useful to see the different methods lined up together. Thanks for the schoolin'! :) – tmoore82 Nov 08 '12 at 21:54