Calling a function name stored in a string variable?

Question

I'm using VBScript and I am wondering if is there any way to call a function name stored in string variable?

Here is my attempt?

a = "b"

sub b() 
    msgbox "c"
end sub

a()

But it always result in an error

Type mismatch 'a'

score 17 · Answer 1 · answered Oct 29 '12 at 18:33

17

The correct answer is: Use GetRef() as in:

Function F(p)
  F = p + p
End Function

Dim FP : Set FP = GetRef("F")

WScript.Echo FP("a")
WScript.Echo FP(123)

Output:

aa
246

answered Oct 29 '12 at 18:33

Ekkehard.Horner

This is a better answer and should be the accepted one. This method also works in ASP Classic. – Jagu Mar 09 '22 at 05:10

score 4 · Accepted Answer · answered Oct 29 '12 at 16:31

4

Seems like e.g. this should work:

Dim a
a = "Call b()"
Eval(a)

Sub b
   ' Do stuff
End Sub

answered Oct 29 '12 at 16:31

KevinH

6

@user433531 Please look at the answer of Ekkehard.Horner, `GetRef` is the right (and secure!) way to do it. `Eval` is not secure, uses global scope, is slow and you cannot easily pass arguments in your function. And a function pointer created by GetRef can be passed around as an object, which is a huge pro. – AutomatedChaos Oct 30 '12 at 06:34

score -3 · Answer 3 · edited May 04 '15 at 13:35

-3

Dim x

Sub b

 print "xxx"' Do stuff
End Sub

x = "call b()"

Execute(eval("x"))

edited May 04 '15 at 13:35

Sport

answered May 04 '15 at 13:30

morten

1

There is no print in VBScript; the task is to call a function via its name. – Ekkehard.Horner May 04 '15 at 13:39
2

Could you please elaborate more your answer adding a little more description about the solution you provide? – abarisone May 04 '15 at 13:49

3 Answers3