12

Can (or should) a macro expansion have side effects? For example, here is a macro which actually goes and grabs the contents of a webpage at compile time:

#lang racket

(require (for-syntax net/url))
(require (for-syntax racket/port))

(define-syntax foo
  (lambda (syntx)
    (datum->syntax #'lex
                   (port->string
                     (get-pure-port
                       (string->url
                         (car (cdr (syntax->datum syntx)))))))))

Then, I can do (foo "http://www.pointlesssites.com/") and it will be replaced with "\r\n<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.0 Transitional//EN\"\r\n\t <and so on>"

Is this good practice, or not? Am I garunteed that Racket will only run this code once? If I add a (display "running...") line to the macro, it only prints once, but I would hate to generalize from one example ...

PS - the reason I'm asking is because I actually think this could be really useful sometimes. For example this is a library which allows you to load (at compile-time) a discovery document from the Google API Discovery service and automatically create wrappers for it. I think it would be really cool if the library actually fetched the discovery document from the web, instead of from a local file.

Also, to give an example of a macro with a different kind of side effects: I once built a macro which translated a small subset of Racket into (eta-expanded) lambda calculus (which is, of course, still runnable in Racket). Whenever the macro finished translating a function, it would store the result in a dictionary so that later invocations of the macro could make use of that function definition in their own translations.

Ord
  • 5,693
  • 5
  • 28
  • 42
  • 1
    Okay, derp. I just realized that the document discovery library I linked to is *reading files* at compile time, which is another form of side effect. This doesn't necessarily mean it's a good thing to be doing, but it is done in real libraries, so ... – Ord Oct 26 '12 at 05:46
  • Re what's a "side effect", I like best your example of memoizing results. (As opposed to the example of reading a file, either local or remote. Reading a JSON discovery document at compile time is really not so different from reading a .RKT file. In fact I almost went that direction for the discovery docs, except I wanted them to work as-is instead of needing to add a #lang line. But the fact it _could_ work like that -- that a JSON discovery document could be a "language" -- is a very cool thing about Racket.) – Greg Hendershott Oct 30 '12 at 17:21
  • 1
    I love SO. Ask a question involving a library, and the author of that library casually leaves you a comment :) I'm still just learning about all of Racket's language-extension/building features, but the more I learn, the more amazed I am. – Ord Oct 30 '12 at 19:03

2 Answers2

14

The short answer

It's fine for macros to have side effects, but you should make sure that your program doesn't change behavior when it's compiled ahead of time.

The longer answer

Macros with side effects are a powerful tool, and can let you do things that make programs much easier to write, or enable things that wouldn't be possible at all. But there are pitfalls to be aware of when you use side effects in macros. Fortunately, Racket provides all the tools to make sure that you can do this correctly.

The simplest kind of macro side effect is where you use some external state to find the code you want to generate. The examples you list in the question (reading Google API description) are of this kind. An even simpler example is the include macro:

#lang racket
(include "my-file.rktl")

This reads the contents of myfile.rktl and drops it in place right where the include form is used.

Now, include isn't a good way to structure your program, but this is a quite benign sort of side effect in the macro. It works the same if you compile the file ahead of time as if you don't, since the result of the include is part of the file.

Another simple example that's not good is something like this:

#lang racket
(define-syntax (show-file stx)
  (printf "using file ~a\n" (syntax-source stx))
  #'(void))

(show-file)

That's because the printf gets executed only at compile time, so if you compile your program that uses show-file ahead of time (as with raco make) then the printf will happen then, and won't happen when the program is run, which probably isn't the intention.

Fortunately, Racket has a technique for letting you write macros like show-file effectively. The basic idea is to leave residual code that actually performs the side effect. In particular, you can use Racket's begin-for-syntax form for this purpose. Here's how I would write show-file:

#lang racket
(define-syntax (show-file stx)
  #`(begin-for-syntax
      (printf "using file ~a\n" #,(syntax-source stx))))

(show-file)

Now, instead of happening when the show-file macro is expanded, the printf happens in the code that show-file generates, with the source embedded in the expanded syntax. That way your program keeps working correctly in the presence of ahead-of-time compilation.

There are other uses of macros with side effects, too. One of the most prominent in Racket is for inter-module communication -- because require doesn't produce values that the requiring module can get, to communicate between modules the most effective way is to use side effects. To make this work in the presence of compilation requires almost exactly the same trick with begin-for-syntax.

This is a topic that the Racket community, and I in particular, have thought a lot about, and there are several academic papers talking about how this works:

Composable and Compilable Macros: You want it when?, Matthew Flatt, ICFP 2002

Advanced Macrology and the Implementation of Typed Scheme, Ryan Culpepper, Sam Tobin-Hochstadt, and Matthew Flatt, Scheme Workshop 2007

Languages as Libraries, Sam Tobin-Hochstadt, Ryan Culpepper, Vincent St-Amour, Matthew Flatt, and Matthias Felleisen, PLDI 2011

Sam Tobin-Hochstadt
  • 4,983
  • 1
  • 21
  • 43
1

In common Lisp the function eval-when allows you to decide when the macro will be expanded.

danielrupis
  • 11
  • 1