awk syntax for getting part of a matched regex

Question

Am sure this is easy, so apologies. In Perl I might do something like

my $str = "foo=23";
$str ~= m/foo=([0-9]+)/
print "foo value is " . $1

ie use parentheses in the regex to be able to refer to part of the match later as $1, $2 etc. What is the equivalent in awk?

Answer 1

Also with GNU awk, use the match() function and capture the parenthesis groups into an array.

str = "foo=23"
match(str, /foo=([0-9]+)/, ary)
print "foo value is " ary[1]

Answer 2

In GNU awk that'd be:

$ cat tst.awk
BEGIN {
   str = "foo=23"
   val = gensub(/foo=([0-9]+)/,"\\1","",str)
   print "foo value is " val
}
$
$ gawk -f tst.awk
foo value is 23

In other awk's you'd need to use [g]sub() and/or match() and/or substr() depending on what else you do/don't want to match on. For example:

$ cat tst.awk
BEGIN {
   str = "foo=23"
   val = substr(str,match(str,/foo=[0-9]+/)+length("foo="))
   print "foo value is " val
}
$ awk -f tst.awk
foo value is 23

You'd need a third arg of ',RLENGTH-length("foo=")' on the substr() call if the target pattern isn't at the end of a line. Make "foo=" a variable if you like and if it itself can contain an RE there's a few more steps necessary.

Answer 3

Why not just use sed?

echo 'foo=23' | sed 's/foo=\([0-9]\+\)/foo value is \1/'

EDIT: If you really need to use awk you'll have to use sub or gsub. See here.

Answer 4

Maybe a bit late for the party, but how about treating '=' as a field separator? Worked a treat for me!

echo foo=23 | awk -F= '{ print $1 " value is " $2 }'