Customizing the finish page of NSIS installer

Question

I want to add a checkbox to the finish page of installer. I have already two checkboxes on finishpage, one for showing readme file and other for opening another link. Now I want to add third checkbox for opening home page of my application.

I am following the steps given in this question as this is the exact thing which I want to achieve Customizing an exsisting NSIS MUI2 page

but the third checkbox is not appearing on finishpage. I am using MUI2.

Here is my code

 

!include "MUI2.nsh" 

var newCheckBox
Function showNewCheckbox
${NSD_CreateCheckbox} 50u 60u 100% 10u "&Launch Google"
Pop $newCheckBox
FunctionEnd

Function launchNewLink
${NSD_GetState} $newCheckBox $0
${If} $0 <> 0
    ExecShell "open" "http://google.com"
${EndIf}
FunctionEnd

Function LaunchLink
  ExecShell "open" "http://yahoo.com"
FunctionEnd


!define MUI_FINISHPAGE_NOAUTOCLOSE
!define MUI_FINISHPAGE_RUN
!define MUI_FINISHPAGE_RUN_NOTCHECKED
!define MUI_FINISHPAGE_RUN_TEXT "Open yahoo"
!define MUI_FINISHPAGE_RUN_FUNCTION "LaunchLink"
!define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
!define MUI_FINISHPAGE_SHOWREADME "${README_FILE}"
!define MUI_PAGE_CUSTOMFUNCTION_SHOW showNewCheckbox
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE launchNewLink
!insertmacro MUI_PAGE_FINISH

Am I missing something??

score 1 · Accepted Answer · answered Oct 15 '12 at 07:45

1

If $newCheckBox is a number != 0 it means the control was created, maybe its just behind the image on the left? Try 120u 175u as the first two numbers.

If you don't need a checkbox you can just use the link:

!define MUI_FINISHPAGE_LINK "My website"
!define MUI_FINISHPAGE_LINK_LOCATION "http://example.com"
!insertmacro MUI_PAGE_FINISH

answered Oct 15 '12 at 07:45

Anders

97,548
12
110
164

Thanks Anders! It was indeed hiding behind the image...It didnt occur to me – Neo Oct 15 '12 at 08:41
Can i change the link color? – Jorge B. Jul 22 '15 at 17:20
@JorgeB.: SetCtlColors – Anders Jul 22 '15 at 22:36
@JorgeB: And what do you expect me to do about it? All of SourceForge have/had problems. Just read the helpfile that is installed with NSIS... – Anders Jul 24 '15 at 13:20
@Anders thank you. I don't expect anything. "API is offline" was my justification to don't know how to change color. – Jorge B. Jul 24 '15 at 13:51
2

`MUI_FINISHPAGE_LINK_COLOR "RRGGBB"` – Jorge B. Jul 24 '15 at 14:58

Customizing the finish page of NSIS installer

1 Answers1