How to write a conditional collect in groovy?

Question

Imagine I have this structure:

class Foo {
   String bar
}

Now imagine I have several instance of Foo whose bar value is baz_1, baz_2, and zab_3.

I want to write a collect statement that only collects the bar values which contain the text baz. I cannot get it to work, but it would look something like this:

def barsOfAllFoos = Foo.getAll().bar
assert barsOfAllFoos == [ 'baz_1', 'baz_2', 'zab_3' ]
def barsWithBaz = barsOfAllFoos.collect{ if( it.contains( "baz" ) { it } ) } // What is the correct syntax for this?
assert barsWithBaz == [ 'baz_1', 'baz_2' ]

score 104 · Accepted Answer · edited May 31 '16 at 02:23

104

You need findAll:

barsOfAllFoos.findAll { it.contains 'baz' }

edited May 31 '16 at 02:23

mkobit

43,979
12
156
150

answered Oct 12 '12 at 20:40

tim_yates

167,322
27
342
338

Awesome, that worked. So when I use `collect` does that require some transformed version of every element in the list I'm "collecting" from to be returned? – ubiquibacon Oct 12 '12 at 20:47
1

collect is used to transform a collection, find will filter it :-) – tim_yates Oct 12 '12 at 20:49
25

And if you want to filter and transform in one step, there's `collectMany`. – ataylor Oct 12 '12 at 21:26
@ataylor thanks. `collectMany` was exactly what i was searching for – aldrin Mar 23 '13 at 09:18
3

I think @Justin_Piper had the best answer here. using collectMany is clunky compared to `findResults` – Snekse Jan 28 '15 at 23:16

Justin Piper · Answer 2 · 2012-10-16T06:33:19.693

If you want to both filter and transform there's lots of ways to do this. After 1.8.1 I'd go with #findResults and a closure that returns null for the elements I want to skip.

def frob(final it) { "frobbed $it" }

final barsWithBaz = barsOfAllFoos.findResults {
    it.contains('baz')? frob(it) : null
}

In earlier versions you can use #findAll and #collect

final barsWithBaz = barsOfAllFoos
                  . findAll { it.contains('baz') }
                  . collect { frob(it) }

Or #sum

final barsWithBaz = barsOfAllFoos.sum([]) {
    it.contains('baz')? [frob(it)] : []
}

Or #inject

final barsWithBaz = barsOfAllFoos.inject([]) {
    l, it -> it.contains('baz')? l << frob(it) : l
}

score 1 · Answer 3 · answered May 27 '16 at 15:01

Using findResults did not work for me... If you want to collect a transformed version of the values matching the condition (for instance a regex search of many lines) you can use collect followed by find or findAll as follows.

def html = """
    <p>this is some example data</p>
    <script type='text/javascript'>
        form.action = 'http://www.example.com/'
        // ...
    </script>
"""

println("Getting url from html...")
// Extract the url needed to upload the form
def url = html.split("\n").collect{line->
    def m = line =~/.*form\.action = '(.+)'.*/
    if (m.matches()) {
        println "Match found!"
        return m[0][1]
    }
}.find()

println "url = '${url}'"

This returns the part of the line matching the given pattern.

Getting url from html...
Match found!
url = 'http://www.example.com/'

How to write a conditional collect in groovy?

3 Answers3