loop through two variable in Haskell

Question

What is the haskell way to do this?

for (int i = 0 ; i < 1000 ; i++)
      for (int j = 0 ; j < 1000 ; j++)
              ret =  foo(i , j )           #I need the return value.

More background: I am solving euler problem 27 , and I have got:

 value a  b =
     let l = length $ takeWhile (isPrime) $ map (\n->n^2 + a * n + b) [0..]
     in (l, a ,b)

The next step is to get a list of tuple by looping through all the possible a and b and then do the following processing:

foldl (\(max,v) (n,a,b)-> if n > max then (n , a * b) else (max ,v) ) (0,0) tuple_list

but I have no idea how to loop through two variables ..Thanks.

Answer 1

Use a nested list comprehension. Here 'foo' is '(,)'':

[ (i,j) | i <- [0 .. 999], j <- [0 .. 999] ]

Or laid out to make the nesting clearer:

[ foo i j
| i <- [0 .. 999]
, j <- [0 .. 999]
]

Answer 2

As well as dons' answer, you can use the list monad:

do 
  i <- [0 .. 999]
  j <- [0 .. 999]
  return (foo i j)

Answer 3

You can also do this nicely using Control.Applicative

module Main where

import Control.Applicative

main :: IO ()
main = mapM_ putStrLn (foo <$> [0..3] <*> [0..3])

foo :: Int -> Int -> String
foo a b = "foo " ++ show a ++ " " ++ show b

Example run:

C:\programming>ghc --make Main.hs
[1 of 1] Compiling Main             ( Main.hs, Main.o )
Linking Main.exe ...

C:\programming>main
foo 0 0
foo 0 1
foo 0 2
foo 0 3
foo 1 0
foo 1 1
foo 1 2
foo 1 3
foo 2 0
foo 2 1
foo 2 2
foo 2 3
foo 3 0
foo 3 1
foo 3 2
foo 3 3